P_Matrix_ElimDataWGroupDerived

@AbapCatalog: {
    sqlViewName: 'PMCONSELIMWGR',
    compiler.compareFilter: true
}
@VDM: {
    viewType: #BASIC,
    private:true
}
@AccessControl: {
    authorizationCheck: #NOT_REQUIRED,
    personalData.blocking: #NOT_REQUIRED
}
@ClientHandling: {
    algorithm:#SESSION_VARIABLE
}
@ObjectModel: {
    usageType: {
        serviceQuality: #X,
        dataClass: #MIXED,
        sizeCategory: #XL
    }
}
@Metadata: {
    ignorePropagatedAnnotations: true
}
define view P_Matrix_ElimDataWGroupDerived
  as select from I_CnsldtnGroupJrnlEntryItem as transaction_data
    inner join   I_CnsldtnVersion        as version_assignment on transaction_data.ConsolidationVersion = version_assignment.ConsolidationVersion
    inner join   I_CnsldtnGroupStructure as unit_structure     on  unit_structure.ConsolidationDimension        =  transaction_data.ConsolidationDimension
                                                               and unit_structure.ConsolidationStructureVersion =  version_assignment.ConsolidationStructureVersion
                                                               and unit_structure.ConsolidationUnit             =  transaction_data.ConsolidationUnit
                                                               and unit_structure.FromFiscalYearPeriod          <= transaction_data.FiscalYearPeriod
                                                               and unit_structure.ToFiscalYearPeriod            >= transaction_data.FiscalYearPeriod
    inner join   I_CnsldtnGroupStructure as punit_structure    on  punit_structure.ConsolidationDimension        =  transaction_data.ConsolidationDimension
                                                               and punit_structure.ConsolidationStructureVersion =  version_assignment.ConsolidationStructureVersion
                                                               and punit_structure.ConsolidationUnit             =  transaction_data.ConsolidationGroup
                                                               and punit_structure.ConsolidationGroup            =  unit_structure.ConsolidationGroup
                                                               and punit_structure.FromFiscalYearPeriod          <= transaction_data.FiscalYearPeriod
                                                               and punit_structure.ToFiscalYearPeriod            >= transaction_data.FiscalYearPeriod
{

  transaction_data.ConsolidationLedger               as rldnr,
  transaction_data.ConsolidationDimension            as rdimen,
  transaction_data.FiscalYear                        as ryear,
  CnsldtnGroupJrnlEntry                              as docnr,
  CnsldtnGroupJrnlEntryItem                          as docln,

  // Common Fields

  GLRecordType             as rrcty,
  transaction_data.ConsolidationVersion              as rvers,

  TransactionCurrency               as rtcur,
  LocalCurrency                     as rhcur,
  transaction_data.GroupCurrency                     as rkcur,
  BaseUnit                          as runit,

  cast('' as shkzg preserving type) as drcrk,
  FiscalPeriod                      as poper,
  FiscalYearPeriod                  as fiscyearper,
  cast('PER' as fincs_period_mode)  as period_mode,
  FiscalPeriod                      as poper_posting,

  DocumentCategory                  as docct,
  Company                           as rcomp,
  transaction_data.ConsolidationUnit                 as rbunit,
  ConsolidationChartOfAccounts      as ritclg,
  FinancialStatementItem            as ritem,
  PartnerConsolidationUnit          as rbuptr,
  transaction_data.ConsolidationGroup                as rcongr,
  CompanyCode                       as robukrs,
  SubItemCategory                   as sityp,
  SubItem                           as subit,
  PostingLevel                      as plevl,
  ConsolidationApportionment        as rpflg,
  CurrencyConversionsDiffType       as rtflg,
  ConsolidationDocumentType         as docty,
  ConsolidationAcquisitionYear      as yracq,
  ConsolidationAcquisitionPeriod    as pracq,
  InvesteeConsolidationUnit         as coicu,
  InvestorConsolidationUnit         as uppcu,

  AmountInTransactionCurrency       as tsl,
  AmountInLocalCurrency             as hsl,
  AmountInGroupCurrency             as ksl,
  CnsldtnQuantityInBaseUnit         as msl,

  DocumentItemText                  as sgtxt,
  ConsolidationPostgItemAutoFlag    as autom,
  BusinessTransactionType           as activ,
  ''                                as bvorg, // missing in I_MatrixCnsldtnFoundation

  PostingDate                       as budat,
  CurrencyTranslationDate           as wsdat,
  RefConsolidationDocumentNumber    as refdocnr,
  ReferenceFiscalYear               as refryear,
  RefConsolidationPostingItem       as refdocln,
  RefConsolidationDocumentType      as refdocct,
  RefBusinessTransactionType        as refactiv,
  CreationDateTime                  as timestamp,
  CreationDate                      as cpudt,
  CreationTime                      as cputm,
  UserID                            as usnam,
  ReverseDocument                   as rvsdocnr,
  ReversedDocument                  as orndocnr,
  InvestmentActivityType            as coiac,
  InvestmentActivity                as coinr,
  ConsolidationDocReversalYear      as revyear,
  ReferenceDocumentType             as awtyp,
  ReferenceDocumentContext          as aworg,
  LogicalSystem                     as logsys,

  // Additional Fields

  ChartOfAccounts                   as ktopl,
  GLAccount                         as racct,
  ''                                as xblnr, // missing in I_MatrixCnsldtnFoundation

  AssignmentReference               as zuonr,

  // Additional Fields - Universal Journal Entry: G/L additional account assignments

  CostCenter                        as rcntr,
  ProfitCenter                      as prctr,
  FunctionalArea                    as rfarea,
  BusinessArea                      as rbusa,
  ControllingArea                   as kokrs,
  Segment                           as segment,
  PartnerCostCenter                 as scntr,
  PartnerProfitCenter               as pprctr,
  PartnerFunctionalArea             as sfarea,
  PartnerBusinessArea               as sbusa,
  PartnerCompany                    as rassc,
  PartnerSegment                    as psegment,
  OrderID                           as aufnr,
  Customer                          as kunnr,
  Supplier                          as lifnr,
  Material                          as matnr,
  MaterialGroup                     as matkl_mm,
  Plant                             as werks,
  FinancialTransactionType          as rmvct,
  WBSElementInternalID              as ps_psp_pnr,
  WBSElementExternalID              as ps_posid,
  Project                           as ps_pspid,

  // Additional Fields - SFIN: Universal Journal Entry - Fixed CO-PA fields

  BillingDocumentType               as fkart,
  SalesOrganization                 as vkorg,
  DistributionChannel               as vtweg,
  OrganizationDivision              as spart,
  SoldMaterial                      as matnr_copa,
  SoldProductGroup                  as matkl,
  CustomerGroup                     as kdgrp,
  CustomerSupplierCountry           as land1,
  CustomerSupplierIndustry          as brsch,
  SalesDistrict                     as bzirk,
  BillToParty                       as kunre,
  ShipToParty                       as kunwe,
  CustomerSupplierCorporateGroup    as konzs
}
where
  PostingLevel = '20'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNSLDTNGROUPJRNLENTRYITEM",
"I_CNSLDTNGROUPSTRUCTURE",
"I_CNSLDTNVERSION"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/