P_Matrix_ElimData

@AbapCatalog: {
    sqlViewName: 'PMCELIM',
    compiler.compareFilter: true
}
@VDM: {
    viewType: #COMPOSITE,
    private:true
}
@AccessControl: {
    authorizationCheck: #NOT_REQUIRED,
    personalData.blocking: #NOT_REQUIRED
}
@ClientHandling: {
    algorithm:#SESSION_VARIABLE
}
@ObjectModel: {
    usageType: {
        serviceQuality: #X,
        dataClass: #MIXED,
        sizeCategory: #XL
    }
}
@Metadata: {
    ignorePropagatedAnnotations: true
}

define view P_Matrix_ElimData
  as select from I_CnsldtnGroupJrnlEntryItem
{
  // Key Fields

  ConsolidationLedger               as rldnr,
  ConsolidationDimension            as rdimen,
  FiscalYear                        as ryear,
  CnsldtnGroupJrnlEntry             as docnr,
  CnsldtnGroupJrnlEntryItem         as docln,

  // Common Fields

  GLRecordType                      as rrcty,
  ConsolidationVersion              as rvers,

  TransactionCurrency               as rtcur,
  LocalCurrency                     as rhcur,
  GroupCurrency                     as rkcur,
  BaseUnit                          as runit,

  cast('' as shkzg preserving type) as drcrk,
  FiscalPeriod                      as poper,
  FiscalYearPeriod                  as fiscyearper,
  cast('PER' as fincs_period_mode)  as period_mode,
  FiscalPeriod                      as poper_posting,

  DocumentCategory                  as docct,
  Company                           as rcomp,
  ConsolidationUnit                 as rbunit,
  ConsolidationChartOfAccounts      as ritclg,
  FinancialStatementItem            as ritem,
  PartnerConsolidationUnit          as rbuptr,
  ConsolidationGroup                as rcongr,
  CompanyCode                       as robukrs,
  SubItemCategory                   as sityp,
  SubItem                           as subit,
  PostingLevel                      as plevl,
  ConsolidationApportionment        as rpflg,
  CurrencyConversionsDiffType       as rtflg,
  ConsolidationDocumentType         as docty,
  ConsolidationAcquisitionYear      as yracq,
  ConsolidationAcquisitionPeriod    as pracq,
  InvesteeConsolidationUnit         as coicu,
  InvestorConsolidationUnit         as uppcu,

  AmountInTransactionCurrency       as tsl,
  AmountInLocalCurrency             as hsl,
  AmountInGroupCurrency             as ksl,
  CnsldtnQuantityInBaseUnit         as msl,

  DocumentItemText                  as sgtxt,
  ConsolidationPostgItemAutoFlag    as autom,
  BusinessTransactionType           as activ,
  ''                                as bvorg, // missing in I_MatrixCnsldtnFoundation

  PostingDate                       as budat,
  CurrencyTranslationDate           as wsdat,
  RefConsolidationDocumentNumber    as refdocnr,
  ReferenceFiscalYear               as refryear,
  RefConsolidationPostingItem       as refdocln,
  RefConsolidationDocumentType      as refdocct,
  RefBusinessTransactionType        as refactiv,
  CreationDateTime                  as timestamp,
  CreationDate                      as cpudt,
  CreationTime                      as cputm,
  UserID                            as usnam,
  ReverseDocument                   as rvsdocnr,
  ReversedDocument                  as orndocnr,
  InvestmentActivityType            as coiac,
  InvestmentActivity                as coinr,
  ConsolidationDocReversalYear      as revyear,
  ReferenceDocumentType             as awtyp,
  ReferenceDocumentContext          as aworg,
  LogicalSystem                     as logsys,

  // Additional Fields

  ChartOfAccounts                   as ktopl,
  GLAccount                         as racct,
  ''                                as xblnr, // missing in I_MatrixCnsldtnFoundation

  AssignmentReference               as zuonr,

  // Additional Fields - Universal Journal Entry: G/L additional account assignments

  CostCenter                        as rcntr,
  ProfitCenter                      as prctr,
  FunctionalArea                    as rfarea,
  BusinessArea                      as rbusa,
  ControllingArea                   as kokrs,
  Segment                           as segment,
  PartnerCostCenter                 as scntr,
  PartnerProfitCenter               as pprctr,
  PartnerFunctionalArea             as sfarea,
  PartnerBusinessArea               as sbusa,
  PartnerCompany                    as rassc,
  PartnerSegment                    as psegment,
  OrderID                           as aufnr,
  Customer                          as kunnr,
  Supplier                          as lifnr,
  Material                          as matnr,
  MaterialGroup                     as matkl_mm,
  Plant                             as werks,
  FinancialTransactionType          as rmvct,
  WBSElementInternalID              as ps_psp_pnr,
  WBSElementExternalID              as ps_posid,
  Project                           as ps_pspid,

  // Additional Fields - SFIN: Universal Journal Entry - Fixed CO-PA fields

  BillingDocumentType               as fkart,
  SalesOrganization                 as vkorg,
  DistributionChannel               as vtweg,
  OrganizationDivision              as spart,
  SoldMaterial                      as matnr_copa,
  SoldProductGroup                  as matkl,
  CustomerGroup                     as kdgrp,
  CustomerSupplierCountry           as land1,
  CustomerSupplierIndustry          as brsch,
  SalesDistrict                     as bzirk,
  BillToParty                       as kunre,
  ShipToParty                       as kunwe,
  CustomerSupplierCorporateGroup    as konzs
}
where
  PostingLevel = '20'

union all select from P_Matrix_PCCData        as transaction_data
  inner join          I_CnsldtnVersion        as version_assignment      on transaction_data.rvers = version_assignment.ConsolidationVersion
  inner join          I_CnsldtnGroupStructure as unit_group_structure    on  unit_group_structure.ConsolidationDimension        =  transaction_data.rdimen
                                                                         and unit_group_structure.ConsolidationStructureVersion =  version_assignment.ConsolidationStructureVersion
                                                                         and unit_group_structure.ConsolidationUnit             =  transaction_data.rbunit
                                                                         and unit_group_structure.ConsolidationGroup            =  transaction_data.rcongr
                                                                         and unit_group_structure.FromFiscalYearPeriod          <= transaction_data.fiscyearper
                                                                         and unit_group_structure.ToFiscalYearPeriod            >= transaction_data.fiscyearper
  inner join          I_CnsldtnGroupStructure as partner_group_structure on  partner_group_structure.ConsolidationDimension        =  transaction_data.rdimen
                                                                         and partner_group_structure.ConsolidationStructureVersion =  version_assignment.ConsolidationStructureVersion
                                                                         and partner_group_structure.ConsolidationUnit             =  transaction_data.rbuptr
                                                                         and partner_group_structure.ConsolidationGroup            =  transaction_data.rcongr
                                                                         and partner_group_structure.FromFiscalYearPeriod          <= transaction_data.fiscyearper
                                                                         and partner_group_structure.ToFiscalYearPeriod            >= transaction_data.fiscyearper

{
  // Key Fields

  rldnr,
  rdimen,
  ryear,
  docnr,
  docln,

  // Common Fields

  rrcty,
  rvers,

  rtcur,
  rhcur,
  rkcur,
  runit,

  drcrk,
  poper,
  fiscyearper,
  period_mode,
  poper_posting,

  docct,
  rcomp,
  rbunit,
  ritclg,
  ritem,
  rbuptr,
  rcongr,
  robukrs,
  sityp,
  subit,
  plevl,
  rpflg,
  rtflg,
  docty,
  yracq,
  pracq,
  coicu,
  uppcu,

  tsl,
  hsl,
  ksl,
  msl,

  sgtxt,
  autom,
  activ,
  bvorg,
  budat,
  wsdat,
  refdocnr,
  refryear,
  refdocln,
  refdocct,
  refactiv,
  timestamp,
  cpudt,
  cputm,
  usnam,
  rvsdocnr,
  orndocnr,
  coiac,
  coinr,
  revyear,
  awtyp,
  aworg,
  logsys,

  // Additional Fields

  ktopl,
  racct,
  xblnr,
  zuonr,

  // Additional Fields - Universal Journal Entry: G/L additional account assignments

  rcntr,
  prctr,
  rfarea,
  rbusa,
  kokrs,
  segment,
  scntr,
  pprctr,
  sfarea,
  sbusa,
  rassc,
  psegment,
  aufnr,
  kunnr,
  lifnr,
  matnr,
  matkl_mm,
  werks,
  rmvct,
  ps_psp_pnr,
  ps_posid,
  ps_pspid,

  // Additional Fields - SFIN: Universal Journal Entry - Fixed CO-PA fields

  fkart,
  vkorg,
  vtweg,
  spart,
  matnr_copa,
  matkl,
  kdgrp,
  land1,
  brsch,
  bzirk,
  kunre,
  kunwe,
  konzs
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNSLDTNGROUPJRNLENTRYITEM",
"I_CNSLDTNGROUPSTRUCTURE",
"I_CNSLDTNVERSION",
"P_MATRIX_PCCDATA"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/