P_MaterialKPIStocksForPhysInv

@AbapCatalog.sqlViewName: 'PMATKPISTKPIN'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.private: true
@VDM.viewType: #COMPOSITE
@ObjectModel: {
                 usageType:{
                              sizeCategory: #L,
                              serviceQuality: #D,
                              dataClass:#TRANSACTIONAL
                           }
              }

define view P_MaterialKPIStocksForPhysInv 
with parameters
    P_StartDate                 : nsdm_reference_startdate,
    P_EndDate                   : nsdm_reference_enddate
  as select from I_MaterialStock_2
{
  key Material,
  key Plant,
  key StorageLocation,
  key Batch,
  key Supplier,
  key SDDocument,
  key SDDocumentItem,
  key WBSElementInternalID,
  key Customer,
  key SpecialStockIdfgStockOwner,    
  key InventoryStockType,
  key InventorySpecialStockType,
  @Semantics.unitOfMeasure: true
  key MaterialBaseUnit,
      CostEstimate,
      CompanyCode,
      
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      sum(MatlWrhsStkQtyInMatlBaseUnit) as MatlWrhsStkQtyInMatlBaseUnit,
      
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      cast(sum( 
        case when MatlDocLatestPostgDate < $parameters.P_StartDate 
        then
         cast( MatlWrhsStkQtyInMatlBaseUnit as abap.dec(25,3)) *  (dats_days_between($parameters.P_StartDate, $parameters.P_EndDate)+1) 
        else
         cast( MatlWrhsStkQtyInMatlBaseUnit as abap.dec(25,3)) *  (dats_days_between(MatlDocLatestPostgDate, $parameters.P_EndDate)+1) 
        end   
      ) as abap.dec(25,3)) as MatlStkQtySumInPeriod,
      _CurrentInvtryPrice,
      _CompanyCode
}
where
  MatlDocLatestPostgDate <= $parameters.P_EndDate and
  ( InventoryStockType = '01' or 
  InventoryStockType = '02' or 
  InventoryStockType = '07' or
  InventoryStockType = '08' )
group by
  Material,
  Plant,
  StorageLocation,
  Batch,
  Supplier,
  SDDocument,
  SDDocumentItem,
  WBSElementInternalID,
  Customer,
  SpecialStockIdfgStockOwner,    
  InventoryStockType,
  InventorySpecialStockType,
  MaterialBaseUnit,
  CostEstimate,
  CompanyCode
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIALSTOCK_2"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENTMATLPRICEBYCOSTEST"
],
"BASE":
[
"I_MATERIALSTOCK_2"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/