P_MassChgSlsDocHdrReadRequest

@EndUserText.label: 'Mass Chg of Sales Doc Header Read Req'
@VDM: {
  viewType: #CONSUMPTION,
  private: true
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'SalesDocument',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #S
   }
}

define view entity P_MassChgSlsDocHdrReadRequest
  as select from I_SalesDocument as SalesDocument
  //Extensibility

//  association [0..1] to E_SalesDocumentBasic as _Extension on SalesDocument.SalesDocument = _Extension.SalesDocument

{

  key SalesDocument.SalesDocument,

      SalesDocumentType,
      //Organization

      SalesOrganization,
      DistributionChannel,
      OrganizationDivision,
      SDDocumentCategory,

      @ObjectModel.text.element: ['SalesGroupName']
      SalesDocument.SalesGroup                as SalesGroup,
      SalesDocument._SalesGroup._Text[1:Language =  $session.system_language].SalesGroupName,

      @ObjectModel.text.element: ['SalesOfficeName']
      SalesDocument.SalesOffice               as SalesOffice,
      SalesDocument._SalesOffice._Text[1:Language =  $session.system_language].SalesOfficeName,

      @ObjectModel.text.element: ['SalesDistrictName']
      SalesDocument.SalesDistrict             as SalesDistrict,
      SalesDocument._SalesDistrict._Text[1:Language =  $session.system_language].SalesDistrictName,

      SalesDocument.RequestedDeliveryDate     as RequestedDeliveryDate,

      @ObjectModel.text.element: ['ShippingConditionName']
      SalesDocument.ShippingCondition         as ShippingCondition,
      SalesDocument._ShippingCondition._Text[1:Language =  $session.system_language].ShippingConditionName,

      @ObjectModel.text.element: ['IncotermsClassificationName']
      SalesDocument.IncotermsClassification   as IncotermsClassification,
      SalesDocument._IncotermsClassification._Text[1:Language =  $session.system_language].IncotermsClassificationName,

      SalesDocument.IncotermsTransferLocation as IncotermsTransferLocation,

      SalesDocument.IncotermsLocation1        as IncotermsLocation1,

      SalesDocument.IncotermsLocation2        as IncotermsLocation2,

      @ObjectModel.text.element: ['IncotermsVersionName']
      SalesDocument.IncotermsVersion          as IncotermsVersion,
      SalesDocument._IncotermsVersion._Text[1:Language =  $session.system_language].IncotermsVersionName,

      SalesDocument.DeliveryBlockReason       as DeliveryBlockReason,

      @ObjectModel.text.element: ['ShippingTypeName']
      SalesDocument.ShippingType              as ShippingType,
      SalesDocument._ShippingType._Text[1:Language =  $session.system_language].ShippingTypeName,

      SalesDocument.PricingDate               as PricingDate,

      SalesDocument.PurchaseOrderByCustomer   as PurchaseOrderByCustomer,

      SalesDocument.CompleteDeliveryIsDefined as CompleteDeliveryIsDefined,

      @ObjectModel.text.element: ['CurrencyName']
      SalesDocument.TransactionCurrency       as TransactionCurrency,
      SalesDocument._TransactionCurrency._Text[1:Language =  $session.system_language].CurrencyName,

      SalesDocument.HeaderBillingBlockReason  as HeaderBillingBlockReason,

      SalesDocument.BillingDocumentDate       as BillingDocumentDate,

      SalesDocument.CustomerPurchaseOrderDate as CustomerPurchaseOrderDate,

      SalesDocument.SalesDocumentDate         as SalesDocumentDate,

      @ObjectModel.text.element: ['SDDocumentReasonText']
      SalesDocument.SDDocumentReason          as SDDocumentReason,
      SalesDocument._SDDocumentReason._Text[1:Language =  $session.system_language].SDDocumentReasonText,

      @ObjectModel.text.element: ['CustomerPaymentTermsName']
      SalesDocument.CustomerPaymentTerms      as CustomerPaymentTerms,
      SalesDocument._CustomerPaymentTerms._Text[1:Language =  $session.system_language].CustomerPaymentTermsName,

      SalesDocument.PaymentMethod             as PaymentMethod
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CURRENCY",
"I_CURRENCYTEXT",
"I_CUSTOMERPAYMENTTERMS",
"I_CUSTOMERPAYMENTTERMSTEXT",
"I_INCOTERMSCLASSIFICATION",
"I_INCOTERMSCLASSIFICATIONTEXT",
"I_INCOTERMSVERSION",
"I_INCOTERMSVERSIONTEXT",
"I_SALESDISTRICT",
"I_SALESDISTRICTTEXT",
"I_SALESDOCUMENT",
"I_SALESGROUP",
"I_SALESGROUPTEXT",
"I_SALESOFFICE",
"I_SALESOFFICETEXT",
"I_SDDOCUMENTREASON",
"I_SDDOCUMENTREASONTEXT",
"I_SHIPPINGCONDITION",
"I_SHIPPINGCONDITIONTEXT",
"I_SHIPPINGTYPE",
"I_SHIPPINGTYPETEXT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/