P_MaintOrderDuration

@AbapCatalog.sqlViewName: 'PMAINTORDDURN'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #BASIC
@VDM.private: true

define view P_MaintOrderDuration
// used for AMDP method (Table Function) determine_order_durations

  as select from afih as afih
      inner join aufk as aufk on aufk.aufnr = afih.aufnr
        left outer join afko as afko on afko.aufnr = aufk.aufnr

  association[1..1] to I_Plant as _MaintenancePlanningPlant on $projection.MaintenancePlanningPlant = _MaintenancePlanningPlant.Plant
{
      // Key

  key afih.aufnr as MaintenanceOrder,

      // Category and Type

      aufk.autyp as  OrderCategory,
      aufk.auart as  OrderType,      

      // Assignments

      afih.iwerk as MaintenancePlanningPlant,
      _MaintenancePlanningPlant.FactoryCalendar as FactoryCalendar,    
      //afpo.pwerk as MRPPlant,


      // Dates

      afko.gstrp                                        as  PlannedStartDate,
      afko.gsuzp                                        as  PlannedStartTime,
      afko.gltrp                                        as  PlannedEndDate,
      afko.gluzp                                        as  PlannedEndTime,
      afko.gstrs                                        as  ScheduledBasicStartDate,
      afko.gsuzs                                        as  ScheduledBasicStartTime,
      afko.gltrs                                        as  ScheduledBasicEndDate,
      afko.gluzs                                        as  ScheduledBasicEndTime,
      afko.ftrms                                        as  ScheduledReleaseDate,
      afko.gstri                                        as  ActualStartDate,
      afko.gsuzi                                        as  ActualStartTime,
      afko.gltri                                        as  ActualEndDate,
      afko.ftrmi                                        as  ActualReleasedDate,
      afko.getri                                        as  ConfirmedEndDate,
      afko.geuzi                                        as  ConfirmedEndTime,
      afko.gstps                                        as  ScheduledForecastedStartDate,
      afko.gsups                                        as  ScheduledForecastedStartTime,
      afko.gltps                                        as  ScheduledForecastedEndDate,
      afko.glups                                        as  ScheduledForecastedEndTime,
      afko.ftrps                                        as  ScheduledFcstdReleaseDate,
      afko.gstpp                                        as  ForecastedStartDate,
      afko.gsupp                                        as  ForecastedStartTime,
      afko.gltpp                                        as  ForecastedEndDate,
      afko.glupp                                        as  ForecastedEndTime,
      afko.gsbtr                                        as  TotalCommitmentDate,
      afko.trmdt                                        as  LastScheduledDate,
      case aufk.pdat1
        when '' then afko.ftrmp
        else aufk.pdat1
      end                                               as  PlannedReleaseDate,
      aufk.pdat2                                        as  PlannedCompletionDate,
      aufk.idat2                                        as  TechnicalCompletionDate,      
      
      // Associations

      _MaintenancePlanningPlant
}
  where ( aufk.autyp = '30' );   //Maintenance Orders only               

  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PLANT",
"AFIH",
"AFKO",
"AUFK"
],
"ASSOCIATED":
[
"I_PLANT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/