@AbapCatalog.sqlViewName: 'PMJOBPCKGOPS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@VDM.private: true
@VDM.viewType: #COMPOSITE
@Metadata.allowExtensions: false
define view P_MaintJobPckgOperations
with parameters
P_MaintenanceJobPackageUUID : eam_mjp_uuid
as select from I_MaintOrderOperAndSubOper as I_MaintenanceOrderOperation
left outer to one join I_MaintJobPackageOperation on I_MaintenanceOrderOperation.MaintenanceOrder = I_MaintJobPackageOperation.MaintenanceOrder
and I_MaintenanceOrderOperation.MaintenanceOrderOperation = I_MaintJobPackageOperation.MaintenanceOrderOperation
and I_MaintenanceOrderOperation.MaintenanceOrderSubOperation = I_MaintJobPackageOperation.MaintenanceOrderSubOperation
and I_MaintJobPackageOperation.MaintenanceJobPackageUUID = $parameters.P_MaintenanceJobPackageUUID
association [0..1] to I_MaintOrderOperTechObj as _MaintOrderOperTechObj on $projection.MaintenanceOrder = _MaintOrderOperTechObj.MaintenanceOrder
and $projection.MaintenanceOrderOperation = _MaintOrderOperTechObj.MaintenanceOrderOperation
association [0..1] to I_EAMProcessPhase as _MaintOrdProcessPhase on $projection.MaintOrdProcessPhaseCode = _MaintOrdProcessPhase.EAMProcessPhaseCode
association [0..1] to I_FunctionalLocation as _MaintOrdOpFunctionalLocation on $projection.OperationFunctionalLocation = _MaintOrdOpFunctionalLocation.FunctionalLocation
{
key I_MaintenanceOrderOperation.MaintenanceOrder,
key I_MaintenanceOrderOperation.MaintenanceOrderOperation,
key I_MaintenanceOrderOperation.MaintenanceOrderSubOperation,
I_MaintenanceOrderOperation._MaintenanceOrder.MaintenanceOrderDesc,
I_MaintenanceOrderOperation.OperationDescription,
// Order Attributes
I_MaintenanceOrderOperation._MaintenanceOrder.MaintenanceOrderType as MaintenanceOrderType,
I_MaintenanceOrderOperation._MaintenanceOrder.MaintenancePlannerGroup as MaintenancePlannerGroup,
I_MaintenanceOrderOperation._MaintenanceOrder.MaintenancePlanningPlant as MaintenancePlanningPlant,
I_MaintenanceOrderOperation._MaintenanceOrder.MaintenancePlant as MaintenancePlant,
I_MaintenanceOrderOperation.MaintOperationExecStageCode,
I_MaintenanceOrderOperation._MaintOperationExecStageCode._MaintOpExecStageCodeText[ 1:LanguageCode = $session.system_language ].MaintOpExecutionStageName,
I_MaintenanceOrderOperation._MaintOperationExecStageCode._MaintOpExecStageCodeText[ 1:LanguageCode = $session.system_language ].MaintOpExecStageShortText,
I_MaintenanceOrderOperation._MaintenanceOrder._LocationAccountAssignment.PlantSection as PlantSection,
I_MaintenanceOrderOperation._MaintenanceOrder._LocationAccountAssignment.ABCIndicator as ABCIndicator,
I_MaintenanceOrderOperation._MaintenanceOrder.Equipment as Equipment,
I_MaintenanceOrderOperation._MaintenanceOrder._Equipment.EquipmentCategory as EquipmentCategory,
cast ( I_MaintenanceOrderOperation._MaintenanceOrder._LocationAccountAssignment.FunctionalLocation as vdm_eam_tplnr preserving type ) as FunctionalLocation,
I_MaintenanceOrderOperation._MaintenanceOrder._LocationAccountAssignment._FunctionalLocation.FunctionalLocationCategory as FunctionalLocationCategory,
I_MaintenanceOrderOperation._MaintenanceOrder.MainWorkCenter as MainWorkCenter,
I_MaintenanceOrderOperation._MaintenanceOrder.MainWorkCenterPlant as MainWorkCenterPlant,
I_MaintenanceOrderOperation._MaintenanceOrder.Assembly as Assembly,
I_MaintenanceOrderOperation._MaintenanceOrder.WBSElementInternalID as WBSElementInternalID,
cast ( I_MaintenanceOrderOperation._MaintenanceOrder.ProjectInternalID as ps_s4_proj_pspnr preserving type ) as ProjectInternalID,
I_MaintenanceOrderOperation._MaintenanceOrder.MaintenanceRevision as MaintenanceRevision,
I_MaintenanceOrderOperation._MaintenanceOrder.ResponsibleCostCenter as ResponsibleCostCenter,
I_MaintenanceOrderOperation._MaintenanceOrder.MaintOrdPersonResponsible as MaintOrdPersonResponsible,
I_MaintenanceOrderOperation._MaintenanceOrder.MaintenanceActivityType as MaintenanceActivityType,
I_MaintenanceOrderOperation._MaintenanceOrder.OperationSystemCondition as OrderSystemCondition,
I_MaintenanceOrderOperation._MaintenanceOrder.MaintOrdBasicStartDate as MaintOrdBasicStartDate,
I_MaintenanceOrderOperation._MaintenanceOrder.MaintOrdBasicEndDate as MaintOrdBasicEndDate,
I_MaintenanceOrderOperation._MaintenanceOrder.LatestAcceptableCompletionDate as LatestAcceptableCompletionDate,
I_MaintenanceOrderOperation._MaintenanceOrder.MaintenancePlan as MaintenancePlan,
I_MaintenanceOrderOperation._MaintenanceOrder.MaintenanceItem as MaintenanceItem,
I_MaintenanceOrderOperation._MaintenanceOrder.MaintOrdProcessPhaseCode as MaintOrdProcessPhaseCode,
I_MaintenanceOrderOperation._MaintenanceOrder.MaintOrdProcessSubPhaseCode as MaintOrdProcessSubPhaseCode,
I_MaintenanceOrderOperation._MaintenanceOrder.MaintPriority,
I_MaintenanceOrderOperation._MaintenanceOrder._MaintenancePriority.MaintPriorityColorCode,
I_MaintenanceOrderOperation._MaintenanceOrder._MaintenancePriority._Text[ 1:Language = $session.system_language ].MaintPriorityDesc,
// Order Operation Attributes
I_MaintenanceOrderOperation.OperationWorkCenterInternalID,
I_MaintenanceOrderOperation._WorkCenter.WorkCenter as OperationWorkCenter,
I_MaintenanceOrderOperation._WorkCenter._Text[ 1:Language = $session.system_language ].WorkCenterText,
I_MaintenanceOrderOperation.OperationControlKey as OperationControlKey,
I_MaintenanceOrderOperation._OperationControlKey._Text[ 1:Language = $session.system_language ].OperationControlProfileName,
I_MaintenanceOrderOperation.OperationSystemCondition as OperationSystemCondition,
I_MaintenanceOrderOperation._OperationSystemCondition._Text[ 1:Language = $session.system_language ].OperationSystemConditionText,
I_MaintenanceOrderOperation.OperationPurgInfoRecdSearchTxt as OperationPurgInfoRecdSearchTxt,
I_MaintenanceOrderOperation.MaintOrdOpProcessPhaseCode as MaintOrdOpProcessPhaseCode,
I_MaintenanceOrderOperation._EAMProcessPhase._EAMProcessPhaseText[ 1:Language = $session.system_language ].EAMProcessPhaseCodeDesc,
I_MaintenanceOrderOperation.MaintOrdOpProcessSubPhaseCode as MaintOrdOpProcessSubPhaseCode,
I_MaintenanceOrderOperation._EAMProcessSubPhase._EAMProcessSubPhaseText[ 1:Language = $session.system_language ].EAMProcessSubPhaseCodeDesc,
I_MaintenanceOrderOperation._OperationPlanningValues.OpActualExecutionStartDate as OpActualExecutionStartDate,
I_MaintenanceOrderOperation._OperationPlanningValues.OpActualExecutionEndDate as OpActualExecutionEndDate,
I_MaintenanceOrderOperation._OperationPlanningValues.OpErlstSchedldExecStrtDte,
I_MaintenanceOrderOperation._OperationPlanningValues.OpErlstSchedldExecEndDte,
I_MaintenanceOrderOperation._OperationPlanningValues.OpLtstSchedldExecStrtDte,
I_MaintenanceOrderOperation._OperationPlanningValues.OpLtstSchedldExecEndDte,
I_MaintenanceOrderOperation._OperationPlanningValues.OperationPlannedWork,
I_MaintenanceOrderOperation._OperationPlanningValues.OperationPlannedWorkUnit,
I_MaintenanceOrderOperation.Equipment as OperationEquipment,
I_MaintenanceOrderOperation._Equipment.EquipmentCategory as MaintJobPckgOpsEquipCategory,
I_MaintenanceOrderOperation._Equipment._EquipmentText[ 1:Language = $session.system_language ].EquipmentName,
cast( I_MaintenanceOrderOperation.FunctionalLocation as vdm_eam_tplnr preserving type ) as OperationFunctionalLocation,
_MaintOrdOpFunctionalLocation._FunctionalLocationLabel.FunctionalLocationLabelName as OpFunctionalLocationLabelName,
I_MaintenanceOrderOperation._FunctionalLocation.FunctionalLocationCategory as MaintJobPckgOpsFuncLocCategory,
I_MaintenanceOrderOperation._FunctionalLocation._FunctionalLocationText[ 1:Language = $session.system_language ].FunctionalLocationName,
I_MaintenanceOrderOperation.CostCtrActivityType,
I_MaintenanceOrderOperation._CostCenterActivityTypeText[ 1: ValidityEndDate = '99991231' and Language = $session.system_language ].CostCtrActivityTypeName,
I_MaintenanceOrderOperation.OperationPersonResponsible,
I_MaintenanceOrderOperation._PersonResponsible.PersonFullName,
_MaintOrderOperTechObj._MaintOrderOperObjectListLink._MaintenanceItemObject.MaintenanceNotification as OperationMaintenanceNotif,
_MaintOrderOperTechObj._MaintOrderOperObjectListLink._MaintenanceItemObject._MaintenanceNotification.NotificationText,
/* Associations */
_MaintOrderOperTechObj,
_MaintOrdProcessPhase
}
where
(
(
I_MaintenanceOrderOperation._StatusObjectActiveStatus [1:StatusCode = 'I0117'].StatusCode is not null
and I_MaintenanceOrderOperation._MaintenanceOrder._MaintOrderTypeControlParam.MaintOrdTypeHasActvPhaseModel = 'X'
)
or(
I_MaintenanceOrderOperation._StatusObjectActiveStatus [1:StatusCode = 'I0002'].StatusCode is not null
and I_MaintenanceOrderOperation._MaintenanceOrder._MaintOrderTypeControlParam.MaintOrdTypeHasActvPhaseModel = ''
)
)
and I_MaintenanceOrderOperation._StatusObjectActiveStatus [1:StatusCode = 'I0013'].StatusCode is null
and I_MaintJobPackageOperation.MaintenanceJobPackageUUID is null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COSTCENTERACTIVITYTYPETEXT",
"I_EAMPROCESSPHASE",
"I_EAMPROCESSPHASETEXT",
"I_EAMPROCESSSUBPHASE",
"I_EAMPROCESSSUBPHASETEXT",
"I_EQUIPMENT",
"I_EQUIPMENTTEXT",
"I_FUNCTIONALLOCATION",
"I_FUNCTIONALLOCATIONLABEL",
"I_FUNCTIONALLOCATIONTEXT",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MAINTENANCEITEMOBJECT",
"I_MAINTENANCENOTIFICATION",
"I_MAINTENANCEORDER",
"I_MAINTJOBPACKAGEOPERATION",
"I_MAINTOPERATIONEXECSTAGECODE",
"I_MAINTOPERATIONSYSTCONDITION",
"I_MAINTOPERATIONSYSTCONDITIONT",
"I_MAINTOPEXECSTAGECODETEXT",
"I_MAINTORDEROPERANDSUBOPER",
"I_MAINTORDEROPEROBJECTLISTLINK",
"I_MAINTORDEROPERPLANNINGVALUES",
"I_MAINTORDEROPERTECHOBJ",
"I_MAINTORDERTYPECONTROLPARAM",
"I_OPERATIONCONTROLPROFILE",
"I_OPERATIONCONTROLPROFILETEXT",
"I_PMNOTIFICATIONPRIORITY",
"I_PMNOTIFICATIONPRIORITYTEXT",
"I_STATUSOBJECTACTIVESTATUS",
"I_WORKCENTER",
"I_WORKCENTERTEXT",
"I_WORKFORCEPERSON"
],
"ASSOCIATED":
[
"I_EAMPROCESSPHASE",
"I_FUNCTIONALLOCATION",
"I_MAINTORDEROPERTECHOBJ"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/