P_LU_SAFTJournal

@AbapCatalog.sqlViewName: 'PLUSAFTJOURNAL'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private: true
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #P
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking : #NOT_REQUIRED
define view P_LU_SAFTJournal 
  as select from I_JournalEntry           as JournalEntry
    inner join   I_LU_SAFTGenericSettings as GenSettings on  GenSettings.CompanyCode    =  JournalEntry.CompanyCode
                                                         and GenSettings.FiscalYearFrom <= JournalEntry.FiscalYear
                                                         and GenSettings.FiscalYearTo   >= JournalEntry.FiscalYear
{

      @ObjectModel.foreignKey.association: '_CompanyCode'
  key JournalEntry.CompanyCode,

      @ObjectModel.foreignKey.association: '_AccountingDocumentType'
  key JournalEntry.AccountingDocumentType                                                                                        as JournalEntryType,
      coalesce(JournalEntry._AccountingDocumentTypeText[1: Language = 'F'].AccountingDocumentTypeName,
      coalesce(JournalEntry._AccountingDocumentTypeText[1: Language = 'E'].AccountingDocumentTypeName,
      coalesce(JournalEntry._AccountingDocumentTypeText[1: Language = $session.system_language].AccountingDocumentTypeName,''))) as JournalDescription,

      PostingDate,
      _CompanyCode,
      _AccountingDocumentType

}

where
  (
       JournalEntry.AccountingDocumentCategory =  ''
    or JournalEntry.AccountingDocumentCategory =  'J'
    or JournalEntry.AccountingDocumentCategory =  'U'
    or JournalEntry.AccountingDocumentCategory =  'L'
  )
  and  JournalEntry.GLBusinessTransactionGroup <> '1'
  and  JournalEntry._JournalEntryItem[1: AccountingDocumentItem = '001'].SpecialGLCode <> 'F'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTINGDOCUMENTTYPETEXT",
"I_JOURNALENTRY",
"I_JOURNALENTRYITEM",
"I_LU_SAFTGENERICSETTINGS"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENTTYPE",
"I_COMPANYCODE"
],
"BASE":
[
"I_JOURNALENTRY"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/