P_JP_TradeCreditBalanceItems4

@VDM.private: true
@VDM.viewType:  #CONSUMPTION
@AbapCatalog.preserveKey:true
@AbapCatalog.sqlViewName: 'PJPTRCEITEMS4'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.type: #CLIENT_DEPENDENT
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'View for Trade Credit Check Detail Items4'
define view P_JP_TradeCreditBalanceItems4
 with parameters
   @Consumption.hidden: true
   P_StartDate: fis_period_date_from,
   @Consumption.hidden: true
   P_EndDate  : fis_period_date_to

  as select from P_JrnlEntrItmToBOPFormItm as Rule 
      left outer join I_GLAccountLineItemRawData as ACDOCA
              on Rule.SourceLedger           = ACDOCA.SourceLedger
             and Rule.CompanyCode            = ACDOCA.CompanyCode   
             and Rule.FiscalYear             = ACDOCA.FiscalYear
             and Rule.AccountingDocument     = ACDOCA.AccountingDocument             
             and Rule.LedgerGLLineItem       = ACDOCA.LedgerGLLineItem
  
      left outer join P_JP_TradeCreditBalanceItems3( P_StartDate: $parameters.P_StartDate, 
                                                     P_EndDate  : $parameters.P_EndDate ) as Item 
              on ACDOCA.CompanyCode            = Item.CompanyCode   
             and ACDOCA.FiscalYear             = Item.FiscalYear
             and ACDOCA.AccountingDocument     = Item.AccountingDocument             
             and ACDOCA.AccountingDocumentItem = Item.AccountingDocumentItem                                                             
{
  key Item.CompanyCode,
  key Item.FiscalYear,
  key Item.AccountingDocument,
  key Item.AccountingDocumentItem,
  key Rule.BOPRptgCntry,
  key Rule.BOPForm,
  key Rule.BOPFormItem,

      Rule.BOPPartnerCntry as CountryCode,  
              
      Item.PostingDate,
      Item.DocumentDate,            
      Item.CashDiscount1DueDate,
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'ClearingJournalEntry' 
      Item.ClearingAccountingDocument,
      
      Item.ClearingJournalEntry,
      
      right( Rule.BOPFormItem, 3 ) as ItemType,
      
      Dats_Add_Months(Item.OriginalPostingDate, 12, 'NULL') as DocDateAddOneYear,

      @Semantics.currencyCode:true
      Item.TransactionCurrency,
      
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Item.AmountInTransactionCurrency,      
      
      Item.IsUsedInPaymentTransaction,
      
      Item.DebitCreditCode,
      Item.ClearingDate,
      Item.ReverseDocument
      
              
} 
  where Rule.BOPRptgCntry = 'JP'

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_GLACCOUNTLINEITEMRAWDATA",
"P_JP_TRADECREDITBALANCEITEMS3",
"P_JRNLENTRITMTOBOPFORMITM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/