P_InvtryMgmtMatlMstrVH

@AbapCatalog.sqlViewName: 'PINVTRYMGMATLVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@VDM.private: true
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass:#MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE 
//@ObjectModel.dataCategory:#VALUE_HELP

@AccessControl.personalData.blocking: #NOT_REQUIRED
@Search.searchable: true

define view P_InvtryMgmtMatlMstrVH
 as select from mara as ma inner join marc as mc on ma.matnr = mc.matnr 
 
association [1..*] to I_MaterialText  as _MaterialText on $projection.Material = _MaterialText.Material
association [1..1] to I_Plant  as _Plant on $projection.Plant = _Plant.Plant
association [1..*] to I_MaterialTypeText as _MaterialTypeText on $projection.MaterialType = _MaterialTypeText.MaterialType
association [1..*] to I_BatchPlant  as _BatchPlant on $projection.Material = _BatchPlant.Material
                                                   and $projection.Plant = _BatchPlant.Plant
association [1..1] to I_BatchCrossPlant  as _BatchCrossPlant on $projection.Material = _BatchCrossPlant.Material
                                         and $projection.batch = _BatchCrossPlant.Batch              
                                                                                            

{ 
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8
  key ma.matnr as Material,
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8
  key mc.werks as Plant,
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8 
  key _BatchPlant.Batch, 
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8     
  _MaterialText[1: Language=$session.system_language].MaterialName,
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8    
  _Plant.PlantName as PlantName,    
  @UI.hidden: true
  case when _BatchPlant.BatchIsMarkedForDeletion is null
    then ''
    else _BatchPlant.BatchIsMarkedForDeletion
  end as BatIsMrkdForDeltnInPlnt,  
//  _BatchPlant.BatchIsMarkedForDeletion as BatIsMrkdForDeltnInPlnt,

  @UI.hidden: true
  case when _BatchPlant.ShelfLifeExpirationDate is null
    then '00000000'
    else _BatchPlant.ShelfLifeExpirationDate
  end as ShelfLifeExpirationDate,   
//  _BatchPlant.ShelfLifeExpirationDate,  

  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8
  ma.mtart as MaterialType,  
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8    
  _MaterialTypeText[1: Language=$session.system_language].MaterialTypeName,
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8    
  ma.prdha as ProductHierarchy,
  @UI.hidden: true
  ma.begru as AuthorizationGroup,
  @UI.hidden: true
  mc.sernp as SerialNumberProfile,
  @UI.hidden: true
  cast(ma.matnr_external as nsdm_mat_external preserving type ) as MaterialExternalID,
  _BatchCrossPlant
}
//where mc.sernp = ''



/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BATCHPLANT",
"I_MATERIALTEXT",
"I_MATERIALTYPETEXT",
"I_PLANT",
"MARA",
"MARC"
],
"ASSOCIATED":
[
"I_BATCHCROSSPLANT",
"I_BATCHPLANT",
"I_MATERIALTEXT",
"I_MATERIALTYPETEXT",
"I_PLANT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/