P_InvoicePriceVariance

@AbapCatalog.sqlViewName: 'PMMINVPRCVARC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType : #CONSUMPTION
@VDM.private: true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST,#GROUP_BY] // Added for extensibility


define view P_InvoicePriceVariance 
 
with parameters 
      P_DisplayCurrency : displaycurrency,
      P_Material        : matnr,
      P_StartDate       : vdm_validitystart,
      P_EndDate         : vdm_validityend
     
      
 as select from P_InvoicePriceVariance2 ( P_DisplayCurrency : $parameters.P_DisplayCurrency,
                                          P_Material : $parameters.P_Material, P_StartDate: $parameters.P_StartDate,
                                                         P_EndDate: $parameters.P_EndDate             ) as PriceVariance
 
  left outer join I_PurchasingCategoryMatlGroup as PurchasingCategoryMatlGroup 
      on PriceVariance.MaterialGroup = PurchasingCategoryMatlGroup.MaterialGroup
  left outer join  I_CalendarDate as Calendar    
      on PriceVariance.PostingDate = Calendar.CalendarDate
 
    

{
//  key PurchaseOrder,

//  key PurchaseOrderItem,

  key MaterialDocumentYear,
  key cast( MaterialDocument as fikz_reginv_invoice )                                     as Invoice,
  key MaterialDocumentItem,

      /* Invoice Date*/
      cast( PostingDate as invdt )                                                        as InvoiceDate,
      Calendar.CalendarYear,
      Calendar.CalendarMonth,
      Calendar.CalendarQuarter,
      Calendar.CalendarWeek,
      Calendar.YearWeek,
      Calendar.YearMonth,
      Calendar.YearQuarter,

      /* Org Data */

      PurchasingOrganization,
      PurchasingGroup,
      CompanyCode,
      Supplier,

      /* Item Data */
      Material,
      PriceVariance.MaterialGroup,

      PurchasingCategoryMatlGroup._PurchasingCategory.PurchasingCategory                            as PurchasingCategory,
      PurchasingCategoryMatlGroup._PurchasingCategory.PurgCatName,

      Plant,
      
      DocNumber,
      
//      @ObjectModel.text.element:  [ 'DocName' ]

//      DocNumber,

//      @Semantics.text: true

//      cast( _DocText.DomainText as mm_a_doctype_name ) as  DocName,


      Currency,
      DisplayCurrency,
      sum (NetPriceAmount) as NetPriceAmount,
      sum(InvoiceAmtInDisplayCurrency)   as InvoiceAmtInDisplayCurrency,      
      sum(QtyInPurchaseOrderPriceUnit) as QtyInPurchaseOrderPriceUnit,
      NetPriceQuantity,
      OrderPriceUnit,
      /*Associations*/
      _Material,
      Quantity,
      PriceVariance._MaterialGroup,
      @Semantics.unitOfMeasure: true
      PurchaseOrderQuantityUnit,
    
      _Plant,
      _Supplier,
      _PurchasingOrganization,
      _PurchasingGroup,
      _CompanyCode,
      _DocText

}
where QtyInPurchaseOrderPriceUnit > 0 

group by  MaterialDocumentYear,
          MaterialDocument,
          MaterialDocumentItem,
          PostingDate,
          Calendar.CalendarYear,
          Calendar.CalendarMonth,
          Calendar.CalendarQuarter,
          Calendar.CalendarWeek,
          Calendar.YearWeek,
          Calendar.YearMonth,
          Calendar.YearQuarter,
          PurchasingOrganization,
          PurchasingGroup,
          CompanyCode,
          Supplier,
          Material,
          PriceVariance.MaterialGroup,
          PurchasingCategoryMatlGroup._PurchasingCategory.PurchasingCategory,
          PurchasingCategoryMatlGroup._PurchasingCategory.PurgCatName,
          Plant,
          DocNumber,
          _DocText.DomainText,
          Currency,
          DisplayCurrency,
          NetPriceQuantity,
          OrderPriceUnit,
          Quantity,
          PurchaseOrderQuantityUnit
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BR_DOMAIN",
"I_CALENDARDATE",
"I_PURCHASINGCATEGORY",
"I_PURCHASINGCATEGORYMATLGROUP",
"P_INVOICEPRICEVARIANCE2"
],
"ASSOCIATED":
[
"I_BR_DOMAIN",
"I_COMPANYCODE",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_PLANT",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER"
],
"BASE":
[
"P_INVOICEPRICEVARIANCE2"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/