P_INFOACCT_LQITEM

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Entry for Information Account'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #A,
  sizeCategory: #S,
  dataClass: #MASTER
}
@VDM.viewType: #BASIC
@VDM.private:true
define view entity P_INFOACCT_LQITEM
  as select from flqacc_info_app           as Entry
           inner join skb1    as Account  on ( Entry.bukrs = Account.bukrs and
                                             ( Entry.saknr_v = Account.saknr and Entry.saknr_b is initial or
                                               Account.saknr between Entry.saknr_v and Entry.saknr_b ) )
{
  key Entry.ktopl                          as ChartOfAccounts,
  key Entry.bukrs                          as CompanyCode,
  key Account.saknr                        as GLAccount,
  key Entry.saknr_v                        as GLAccountFrom,
  key Entry.saknr_b                        as GLAccountTo,

  key case
         when Entry.saknr_b is initial
            then 1
         else case
                when Entry.saknr_v = Entry.saknr_b
                   then 2
                else 3 end
      end                                  as PriorityOfRule,

      Entry.sign                           as SignOfIncludeExclude,
      Entry.lqpos_d                        as DefaultLiquidityItem,
      Entry.further                        as FurtherEvaluation
} where Entry.bukrs is not initial and Account.saknr <> ''

union all  select from flqacc_info_app as Entry
           inner join t001                    on  Entry.bukrs = '' and t001.ktopl = Entry.ktopl
           inner join skb1      as Account    on  t001.bukrs = Account.bukrs and
                                                  ( Entry.saknr_v = Account.saknr and Entry.saknr_b is initial or
                                                    Account.saknr between Entry.saknr_v and Entry.saknr_b )

{

  key Entry.ktopl                          as ChartOfAccounts,
  key t001.bukrs                           as CompanyCode,
  key Account.saknr                        as GLAccount,

  key Entry.saknr_v                        as GLAccountFrom,
  key Entry.saknr_b                        as GLAccountTo,

  key case
         when Entry.saknr_b is initial
            then 4
         else case
                when Entry.saknr_v = Entry.saknr_b
                   then 5
                else 6 end
      end                                  as PriorityOfRule,

      Entry.sign                           as SignOfIncludeExclude,
      Entry.lqpos_d                        as DefaultLiquidityItem,
      Entry.further                        as FurtherEvaluation

} where Entry.bukrs is initial and Account.saknr <> ''



/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FLQACC_INFO_APP",
"SKB1",
"T001"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/