P_HR_StRpTaxReturnPeriodDetail

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@VDM.private:true
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XL,
  dataClass: #MIXED
}
@EndUserText.label: 'Croatia Tax return period detail'
define view entity P_HR_StRpTaxReturnPeriodDetail

  with parameters

    P_StatryRptgEntity      : srf_reporting_entity,
    P_StatryRptCategory     : srf_rep_cat_id,
    P_StatryRptRunID        : srf_report_run_id,
    P_ReportingCountry      : land1,
    P_FromReportingDate     : fis_period_date_from,
    P_ToReportingDate       : fis_period_date_to,
    P_TaxIsDeferredRelevant : figen_deferred_check,
    P_TaxIsMossRelevant     : figen_moss_check,
    P_TaxBoxConfiguration   : figen_tdt_taxbox_config


  as select from I_StRpTaxReturnBoxCube(  P_TaxIsDeferredRelevant : $parameters.P_TaxIsDeferredRelevant,
                                          P_TaxIsMossRelevant     : $parameters.P_TaxIsMossRelevant,
                                          P_StatryRptgEntity      : $parameters.P_StatryRptgEntity ,
                                          P_StatryRptCategory     : $parameters.P_StatryRptCategory,
                                          P_StatryRptRunID        : $parameters.P_StatryRptRunID,
                                          P_ReportingCountry      : $parameters.P_ReportingCountry,
                                          P_TaxBoxConfiguration   : $parameters.P_TaxBoxConfiguration) as TaxReturn

  association [0..1] to I_OperationalAcctgDocItem as _CustomerLineItem on  _CustomerLineItem.CompanyCode            = $projection.CompanyCode
                                                                       and _CustomerLineItem.AccountingDocument     = $projection.AccountingDocument
                                                                       and _CustomerLineItem.FiscalYear             = $projection.FiscalYear
                                                                       and _CustomerLineItem.AccountingDocumentItem = $projection.TaxItem
                                                                       and _CustomerLineItem.Customer               = $projection.Customer
                                                                       and (
                                                                          _CustomerLineItem.FinancialAccountType    = 'D'
                                                                          or _CustomerLineItem.FinancialAccountType = 'K'
                                                                        )
{
  key           TaxReturn.CompanyCode,
  key           TaxReturn.AccountingDocument,
  key           TaxReturn.FiscalYear,
  key           TaxReturn.TaxItem,
  key           TaxReturn.StatryRptgEntity,
  key           TaxReturn.StatryRptCategory,
  key           TaxReturn.StatryRptRunID,
  key           TaxReturn.TransactionTypeDetermination,
  key           TaxReturn.TaxCode,
  key           TaxReturn.TaxBoxStrucValidityStartDate,
                TaxReturn.TaxBoxStrucValidityEndDate,
                TaxReturn.ReportingDate,
                TaxReturn.Customer,
                TaxReturn.UnifiedTaxBoxStructureType,
                TaxReturn.TaxBoxStructureType,
                TaxReturn.TaxBox,
                cast( ( case when  TaxReturn.TaxNumber2 <> '' then TaxReturn.TaxNumber2
                              when _CustomerLineItem.VATRegistration is not null and _CustomerLineItem.VATRegistration <> '' then lpad( (substring(  _CustomerLineItem.VATRegistration , 3, 18) ), 11, '0' )
                              when TaxReturn.TaxNumber2 is null and _CustomerLineItem.VATRegistration is null then  ''   end   ) as fiisvat_vatreg_without_prefix ) as VATRegistrationWithoutPrefix,
                TaxReturn.ReportingCountry,
                TaxReturn.ReportingCurrency,
                @Semantics.amount.currencyCode: 'ReportingCurrency'
                TaxReturn.AmountInReportingCurrency
}
where
      TaxReturn.TaxBoxStrucValidityStartDate <= $parameters.P_ToReportingDate
  and TaxReturn.TaxBoxStrucValidityEndDate   >= $parameters.P_FromReportingDate
  and TaxReturn.StatryRptgEntity             = $parameters.P_StatryRptgEntity
  and TaxReturn.StatryRptCategory            = $parameters.P_StatryRptCategory
  and TaxReturn.StatryRptRunID               = $parameters.P_StatryRptRunID
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_OPERATIONALACCTGDOCITEM",
"I_STRPTAXRETURNBOXCUBE"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/