P_GteeMBillingElementEntryOpen

@AbapCatalog.sqlViewName: 'PGMGBEEOPEN'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@VDM.viewType: #COMPOSITE
@VDM.private:true
@ObjectModel: {
     usageType: {
         dataClass: #MIXED,
         serviceQuality: #P,
         sizeCategory: #XL
     }
}

define view P_GteeMBillingElementEntryOpen
  as select from I_GteeMBillingElementEntry as BillingElementEntry
  association [0..1] to I_GteeMBillingElementEntryFlw as _BillingElementEntrFlwOne on $projection.GteeMBillgElmntEntrItmUUID = _BillingElementEntrFlwOne.GteeMBillgElmntEntrItmUUID
                                                                                   and _BillingElementEntrFlwOne.DocumentBillingStatus <> 'D'
{
  key BillingElementEntry.GteeMBillgElmntEntrItmUUID     as GteeMBillgElmntEntrItmUUID,
      BillingElementEntry.GteeMBillingElementUUID        as GteeMBillingElementUUID,

      //Main Billing Account Assignments

      @ObjectModel.foreignKey.association: '_Grant'
      BillingElementEntry.GrantID                         as GrantID,
      @ObjectModel.foreignKey.association: '_SponsoredProgramCore'
      BillingElementEntry.SponsoredProgram                as SponsoredProgram,

      //Currencies

      @Semantics.currencyCode: true
      BillingElementEntry.DocumentCurrency              as DocumentCurrency,

      //Amounts

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      BillingElementEntry.OriginalRevenueAmtInDocCrcy    as OriginalRevenueAmtInDocCrcy,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      BillingElementEntry.ToBeWrittenOffAmtInDocCrcy     as ToBeWrittenOffAmtInDocCrcy,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      BillingElementEntry.ToBePostponedAmtInDocCrcy      as ToBePostponedAmtInDocCrcy,

      //Journal Reference

      BillingElementEntry.Ledger                         as Ledger,
      BillingElementEntry.CompanyCode                    as CompanyCode,
      BillingElementEntry.FiscalYear                     as FiscalYear,
      BillingElementEntry.AccountingDocument             as AccountingDocument,
      BillingElementEntry.LedgerGLLineItem               as LedgerGLLineItem,

      //Admin fields

      @Semantics.user.createdBy: true
      BillingElementEntry.GteeMBillgElmntEntrCrtedByUsr  as GteeMBillgElmntEntrCrtedByUsr,
      @Semantics.systemTime.createdAt: true
      BillingElementEntry.GteeMBillgElmntEntrCrteDteTme  as GteeMBillgElmntEntrCrteDteTme,
      @Semantics.user.lastChangedBy: true
      BillingElementEntry.GteeMBillgElmntEntrChgdByUsr   as GteeMBillgElmntEntrChgdByUsr,
      @Semantics.systemTime.lastChangedAt: true
      BillingElementEntry.GteeMBillingElmntEntrChgDteTme as GteeMBillingElmntEntrChgDteTme,

      // Association

      BillingElementEntry._Grant,
      BillingElementEntry._SponsoredProgramCore,
      BillingElementEntry._GteeMBillingElementEntryFlw,
      BillingElementEntry._GteeMBillingElement
      
} where _BillingElementEntrFlwOne.GteeMBillgElmntEntrItmFlowUUID is null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_GTEEMBILLINGELEMENTENTRY",
"I_GTEEMBILLINGELEMENTENTRYFLW"
],
"ASSOCIATED":
[
"I_GRANT",
"I_GTEEMBILLINGELEMENT",
"I_GTEEMBILLINGELEMENTENTRYFLW",
"I_SPONSOREDPROGRAMCORE"
],
"BASE":
[
"I_GTEEMBILLINGELEMENTENTRY"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/