P_GoodsReceiptDataSITLoc

@AbapCatalog.sqlViewName: 'PGOODSRECDATASLC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass:#MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.private: true
@VDM.viewType: #COMPOSITE
define view P_GoodsReceiptDataSITLoc
  as select from I_PurchasingDocumentHistoryBsc as _purchDoc

  association [1..1] to I_GoodsMovementDocument as _matDoc             on  _purchDoc.PurchasingHistoryDocument     = _matDoc.MaterialDocument
                                                                       and _purchDoc.PurchasingHistoryDocumentItem = _matDoc.MaterialDocumentItem
                                                                       and _purchDoc.PurchasingHistoryDocumentYear = _matDoc.MaterialDocumentYear
                                                                       and _purchDoc.PurchasingDocument            = _matDoc.PurchaseOrder
                                                                       and _purchDoc.PurchasingDocumentItem        = _matDoc.PurchaseOrderItem  
                                                                       and _purchDoc.Material                      = _matDoc.Material                                                                                                                                                         
                                                                       and _matDoc.MaterialDocumentRecordType      = 'MDOC'

  association [1..1] to P_GetLastPostingDate    as _GetLastPostingDate on  $projection.PurchaseOrder     = _GetLastPostingDate.PurchaseOrder
                                                                       and $projection.PurchaseOrderItem = _GetLastPostingDate.PurchaseOrderItem

{

  key _purchDoc.PurchasingHistoryDocument                                                                                       as MaterialDocument,
  key _purchDoc.PurchasingHistoryDocumentItem                                                                                   as MaterialDocumentItem,
  key _purchDoc.PurchasingHistoryDocumentYear                                                                                   as MaterialDocumentYear,
  key _purchDoc.PurchasingDocument                                                                                              as PurchaseOrder,
  key _purchDoc.PurchasingDocumentItem                                                                                          as PurchaseOrderItem,

      cast(_purchDoc.Plant              as nsdm_gr_werks preserving type)                                                       as ReceivingPlant,
      _purchDoc.Material                                                                                                        as Material,
      cast(_matDoc.CompanyCode          as nsdm_gr_bukrs preserving type)                                                       as ReceivingCompanyCode,
      cast(_matDoc._Plant.PlantName     as nsdm_gr_name preserving type)                                                        as ReceivingPlantName,
      cast(_purchDoc.GoodsMovementType  as nsdm_gr_bwart preserving type)                                                       as GoodsReceiptMovementType,
      cast(_purchDoc.PostingDate        as nsdm_gr_budat preserving type)                                                       as GoodsReceiptPostingDate,
      cast(_matDoc.QuantityInBaseUnit   as nsdm_gr_bstmg preserving type)                                                       as GoodsReceiptQuantity,
      cast(_matDoc.GoodsReceiptQtyInOrderUnit as nsdm_gr_bstmg preserving type)                                                 as GoodsReceiptQtyInOrderUnit, //2813353

      cast(_matDoc.MaterialBaseUnit     as nsdm_gr_meins preserving type)                                                       as GoodsReceiptBaseUnit,
      cast(_purchDoc.CreatedByUser      as mmim_gr_created_by_user)                                                             as GRCreatedByUser,
      _matDoc.GoodsMovementIsCancelled                                                                                          as GoodsReceiptIsCanceled,
      _matDoc.ReversedMaterialDocument                                                                                          as GRReveralMaterialDocument,
      
      _GetLastPostingDate,
      
      cast( _purchDoc.DeliveryDocument as mmim_gr_delivery_document )                                                           as GoodsReceiptForDeliveryDoc,
      cast( _purchDoc.DeliveryDocumentItem as mmim_gr_delivery_document_item)                                                   as GoodsReceiptForDeliveryDocItem,
      cast( _matDoc._DeliveryDocumentItem.CreationDate as mmim_gr_deliv_doc_itm_crtn_dte  preserving type)                      as GoodsReceiptDelivDocItmCrtnDte,
      cast( _matDoc._DeliveryDocumentItem.ActualDeliveredQtyInBaseUnit as mmim_gr_deliv_doc_itm_quantity )                      as GoodsReceiptDelivDocItmQty,
      cast( _matDoc._DeliveryDocumentItem.Batch as mmim_gr_deliv_doc_itm_batch preserving type)                                 as GoodsReceiptDelivDocItmBatch,
      cast( _matDoc._DeliveryDocument.DeliveryDocumentType as mmim_gr_deliv_doc_type preserving type)                           as GoodsReceiptDelivDocType,
      cast( _matDoc._DeliveryDocument.SDDocumentCategory as mmim_gr_deliv_doc_cat preserving type)                              as GoodsReceiptDelivDocCat,
      cast( _matDoc._DeliveryDocumentItem.GoodsMovementStatus as mmim_gr_deliv_doc_itm_status preserving type)                  as GoodsReceiptDelivDocItmStatus,
      cast( DATS_TIMS_TO_TSTMP(_matDoc.CreationDate, _matDoc.CreationTime, 'UTC', $session.client, 'NULL' )
                                                                                          as mmim_date_time )                   as GoodsReceiptUTCDateTime,
      _purchDoc.Quantity                                                                                                        as QuantityInPurchaseOrderUnit                                                                                          

}
where
     _purchDoc.PurchasingHistoryCategory = 'E'
 and _matDoc.IsEffectiveGoodsMovement    = 'X' 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DELIVERYDOCUMENT",
"I_DELIVERYDOCUMENTITEM",
"I_GOODSMOVEMENTDOCUMENT",
"I_PLANT",
"I_PURCHASINGDOCUMENTHISTORYBSC"
],
"ASSOCIATED":
[
"I_GOODSMOVEMENTDOCUMENT",
"P_GETLASTPOSTINGDATE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/