P_GLAccountHierNodeBySemTag_2

@Metadata.allowExtensions: false
@AbapCatalog: {
  sqlViewName: 'PFIGLHNSEMTAG2',
  compiler.compareFilter: true,
  preserveKey:true
}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.representativeKey: 'HierarchyNode'
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
  dataClass: #CUSTOMIZING,
  serviceQuality: #A,
  sizeCategory: #S
}
@AbapCatalog.buffering:{
  status: #ACTIVE,
  type: #FULL
}
@VDM.private:true
@VDM.viewType: #BASIC


define view P_GLAccountHierNodeBySemTag_2

  //*****************************************************************************

  // Nodes for hierarchies defined with OB58

  //*****************************************************************************


  as select from hrrp_node_n
    inner join   finsc_fagl2semta on  finsc_fagl2semta.ergsl = hrrp_node_n.nodevalue
                                  and finsc_fagl2semta.versn = hrrp_node_n.hryid

  association [0..1] to I_SemanticTag        as _SemanticTag on $projection.SemanticTag = _SemanticTag.SemanticTag
  association [0..*] to I_GLAccountHierarchy as _Hierarchy   on $projection.GLAccountHierarchy = _Hierarchy.GLAccountHierarchy

{

      @ObjectModel.foreignKey.association: '_Hierarchy'
  key hrrp_node_n.hryid_42                as GLAccountHierarchy,
  key hrrp_node_n.hrynode                 as HierarchyNode,
      @ObjectModel.foreignKey.association: '_SemanticTag'
  key finsc_fagl2semta.fins_sem_tag       as SemanticTag,
      cast('HierarchyNode' as fieldname ) as HierarchyNodeType,
      _SemanticTag,
      _Hierarchy
      //      'OB_N'                        as HierarchySource


}
where
      hrrp_node_n.hrytyp     = 'FSVN'
  and hrrp_node_n.nodetype   = 'N'
  and hrrp_node_n.hryvalfrom <= $session.system_date
  and hrrp_node_n.hryvalto   >= $session.system_date
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FINSC_FAGL2SEMTA",
"HRRP_NODE_N"
],
"ASSOCIATED":
[
"I_GLACCOUNTHIERARCHY",
"I_SEMANTICTAG"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/