P_FixedAssetAssgmt

@AbapCatalog: { sqlViewName: 'PFASSETASSGMT', preserveKey: true, compiler.compareFilter: true }
@VDM.viewType: #BASIC
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

define view P_FixedAssetAssgmt
  as select from           anlz
    left outer to one join tka02                                                           on  tka02.bukrs = anlz.bukrs
                                                                                           and tka02.gsber = ''
    inner join             P_TF_AssetRedesignSwitchStatus( P_SAPClient : $session.client ) on P_TF_AssetRedesignSwitchStatus.IsActive = ''
{
  key anlz.bukrs                                                         as CompanyCode,
  key anlz.anln1                                                         as MasterFixedAsset,
  key anlz.anln2                                                         as FixedAsset,
  key anlz.bdatu                                                         as ValidityEndDate,

      tka02.kokrs                                                        as ControllingArea,
      anlz.adatu                                                         as ValidityStartDate,
      anlz.kfzkz                                                         as VehicleLicensePlateNumber,
      anlz.kostl                                                         as CostCenter,
      anlz.werks                                                         as Plant,
      anlz.gsber                                                         as BusinessArea,
      anlz.stort                                                         as AssetLocation,
      anlz.raumn                                                         as Room,
      anlz.lstar                                                         as CostCtrActivityType,
      anlz.caufn                                                         as InternalOrder,
      anlz.xstil                                                         as IsShutDown,
      anlz.kostlv                                                        as ResponsibleCostCenter,
      anlz.pernr                                                         as PersonnelNumber,
      anlz.iaufn                                                         as MaintenanceOrder,
      anlz.txjcd                                                         as TaxJurisdiction,
      anlz.geber                                                         as Fund,
      anlz.ps_psp_pnr2                                                   as WBSElementInternalID,
      cast(anlz.ps_psp_pnr2 as fis_wbsint_no_conv preserving type)       as WBSElementInternalID_2,
      cast(anlz.imkey as recaimkeyfi preserving type)                    as REInternalFinNumber,
      cast(anlz.imkey as faa_deprecated_real_estate_obj preserving type) as RealEstateObject,
      anlz.prctr                                                         as ProfitCenter,
      anlz.segment                                                       as Segment,
      anlz.fkber                                                         as FunctionalArea,
      anlz.msfak                                                         as ShiftOperationFactor,
      anlz.grant_nbr                                                     as GrantID,
      anlz.budget_pd                                                     as BudgetPeriod,
      anlz.fistl                                                         as FundsCenter,
      anlz.tplnr                                                         as FunctionalLocation,
      cast('' as bupla)                                                  as BusinessPlace,
      cast('CLASSIC' as faa_authcntxt)                                   as AssetAuthorizationContext,
      cast('' as awtyp)                                                  as ReferenceDocumentType,
      cast('' as awsys)                                                  as LogicalSystem,
      cast('' as aworg)                                                  as ReferenceDocumentContext,
      cast('' as awref)                                                  as ReferenceDocument
}

union all select from    faat_md_tdd
  left outer to one join tka02                                                           on  tka02.bukrs = faat_md_tdd.comp_code
                                                                                         and tka02.gsber = ''
  inner join             P_TF_AssetRedesignSwitchStatus( P_SAPClient : $session.client ) on P_TF_AssetRedesignSwitchStatus.IsActive = 'X'
{
  key  faat_md_tdd.comp_code                                                               as CompanyCode,
  key  faat_md_tdd.asset_no                                                                as MasterFixedAsset,
  key  faat_md_tdd.asset_subno                                                             as FixedAsset,
  key  faat_md_tdd.valid_to_date                                                           as ValidityEndDate,

       tka02.kokrs                                                                         as ControllingArea,
       faat_md_tdd.valid_from_date                                                         as ValidityStartDate,
       faat_md_tdd.car_license_plate                                                       as VehicleLicensePlateNumber,
       faat_md_tdd.cost_center                                                             as CostCenter,
       faat_md_tdd.plant                                                                   as Plant,
       faat_md_tdd.business_area                                                           as BusinessArea,
       faat_md_tdd.location                                                                as AssetLocation,
       faat_md_tdd.room                                                                    as Room,
       faat_md_tdd.activity_type                                                           as CostCtrActivityType,
       faat_md_tdd.internal_order                                                          as InternalOrder,
       cast('' as xstil)                                                                   as IsShutDown, // moved to faat_md_val_tdd

       faat_md_tdd.responsible_cost_center                                                 as ResponsibleCostCenter,
       faat_md_tdd.personnel_number                                                        as PersonnelNumber,
       cast('' as iaufn)                                                                   as MaintenanceOrder, // deleted

       faat_md_tdd.tax_jurisdiction                                                        as TaxJurisdiction,
       faat_md_tdd.fund                                                                    as Fund,
       cast(faat_md_tdd.wbs_element as am_ipsnr)                                           as WBSElementInternalID,
       cast(faat_md_tdd.wbs_element as fis_wbsint_no_conv preserving type)                 as WBSElementInternalID_2,
       cast(faat_md_tdd.real_estate_key  as recaimkeyfi preserving type)                   as REInternalFinNumber,
       cast(faat_md_tdd.real_estate_key as faa_deprecated_real_estate_obj preserving type) as RealEstateObject,
       faat_md_tdd.profit_center                                                           as ProfitCenter,
       faat_md_tdd.segment                                                                 as Segment,
       faat_md_tdd.functional_area                                                         as FunctionalArea,
       cast('0' as msfak)                                                                  as ShiftOperationFactor, // moved to faat_md_val_tdd

       faat_md_tdd.grant_id                                                                as GrantID,
       faat_md_tdd.budget_period                                                           as BudgetPeriod,
       faat_md_tdd.funds_center                                                            as FundsCenter,
       cast('' as tplnr)                                                                   as FunctionalLocation, // deleted

       faat_md_tdd.business_place                                                          as BusinessPlace,
       cast('NEW' as faa_authcntxt)                                                        as AssetAuthorizationContext,
       faat_md_tdd.awtyp                                                                   as ReferenceDocumentType,
       faat_md_tdd.awsys                                                                   as LogicalSystem,
       faat_md_tdd.aworg                                                                   as ReferenceDocumentContext,
       faat_md_tdd.awref                                                                   as ReferenceDocument
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ANLZ",
"FAAT_MD_TDD",
"TKA02"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/