P_FicaDocumentItems

@AbapCatalog.sqlViewName: 'PBOPFICAITM'
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
@VDM.viewType: #COMPOSITE
@VDM.private: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling: { type: #INHERITED, algorithm: #SESSION_VARIABLE }
define view P_FicaDocumentItems
  as

  select distinct from I_CADocumentBPItemPhysical as fica_itm_bp

{
  key fica_itm_bp.CompanyCode,
  key fica_itm_bp.CADocumentNumber,
  key cast( '0000' as  opupk_kk)              as CAGLItemNumber,
  key fica_itm_bp.CASubItemNumber,
  key fica_itm_bp.CABPItemNumber,
      fica_itm_bp.CAPostingDate,
      fica_itm_bp.ChartOfAccounts,
      fica_itm_bp.CAReconciliationAccount as GLAccount,
      fica_itm_bp.TaxCode,
      _DocType.CADocumentType,
      fica_itm_bp.CAAmountInTransactionCurrency,
      fica_itm_bp.TransactionCurrency,
      fica_itm_bp.CompanyCodeCurrency,
      fica_itm_bp.CAAmountInLocalCurrency,
      fica_itm_bp.CAClearingDate,
      fica_itm_bp.CAClearingDocumentNumber,
      cast( '0000' as fis_auggj preserving type)           as ClearingDocFiscalYear,
      _DocHeader.CAReversedDocumentNumber,
      _DocHeader.CAReversalDocumentNumber,
      fica_itm_bp.BusinessPartner,
      _BusinessPartner._CurrentDefaultAddress._Address.Country,
      fica_itm_bp.PartnerCompany, //[non-]affiliated

      //    D indicates that this is a BP Item

      cast('D' as farp_koart )                                 as FinancialAccountType,
      cast('' as ldgrp_kk )                                    as LedgerGroup
}

union all select distinct from I_CADocumentGLItem         as fica_itm_gl
  inner join                   I_CADocumentBPItemPhysical as fica_itm_bp on  fica_itm_gl.CompanyCode      = fica_itm_bp.CompanyCode
                                                                         and fica_itm_gl.CADocumentNumber = fica_itm_bp.CADocumentNumber
                                                                         and fica_itm_bp.CASubItemNumber  = '000'
{
  key fica_itm_gl.CompanyCode,
  key fica_itm_gl.CADocumentNumber,
  key fica_itm_gl.CAGLItemNumber,
  key cast( '' as  opupz_kk) as CASubItemNumber,
  key cast( '' as  opupk_kk) as CABPItemNumber,
      fica_itm_bp.CAPostingDate,
      fica_itm_gl.ChartOfAccounts,
      fica_itm_gl.GLAccount,
      fica_itm_gl.TaxCode,      
      fica_itm_gl._DocHeader._DocType.CADocumentType,
      fica_itm_gl.CAAmountInTransactionCurrency,
      fica_itm_gl.TransactionCurrency,
      fica_itm_bp.CompanyCodeCurrency,
      fica_itm_gl.CAAmountInLocalCurrency,
      fica_itm_bp.CAClearingDate,
      fica_itm_bp.CAClearingDocumentNumber,
      cast( '0000' as fis_auggj preserving type) as ClearingDocFiscalYear,
      fica_itm_bp._DocHeader.CAReversedDocumentNumber,
      fica_itm_bp._DocHeader.CAReversalDocumentNumber,
      fica_itm_bp.BusinessPartner,
      fica_itm_bp._BusinessPartner._CurrentDefaultAddress._Address.Country,
      fica_itm_gl.PartnerCompany, //[non-]affiliated

      cast('S' as farp_koart )                                 as FinancialAccountType,
      fica_itm_gl.LedgerGroup                                  as LedgerGroup  
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_BPCURRENTDEFAULTADDRESS",
"I_BUSINESSPARTNER",
"I_CADOCUMENTBPITEMPHYSICAL",
"I_CADOCUMENTGLITEM",
"I_CADOCUMENTHEADER",
"I_CADOCUMENTTYPE"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/