P_FSVHierarchy

@VDM.private:true
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'PFSVHIER'
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@AbapCatalog.compiler.compareFilter: true
define view P_FSVHierarchy
  as select from I_FinancialStatementItem
    inner join   t011 on I_FinancialStatementItem.FinancialStatementVariant = t011.versn
{
  key cast(I_FinancialStatementItem.HierarchyNode as abap.char(50))                                          as HierarchyUniqueNodeID,
  key cast (I_FinancialStatementItem.ParentNode as abap.char(50))                                            as UniqueParentID,
  key I_FinancialStatementItem.FinancialStatementVariant                                                     as versn,
  key I_FinancialStatementItem.FinancialStatementItem                                                        as ergsl,
  key t011.ktopl                                                                                             as ktopl,
  key cast ('' as saknr)                                                                                     as saknr,
  key cast ('' as fkber)                                                                                     as fkber,
      I_FinancialStatementItem.NodeType                                                                      as type,
      cast ('' as abap.char(50))                                                                             as Description,
      cast ('' as xsoll_f02e)                                                                                as xsoll,
      cast ('' as xhabn_f02e)                                                                                as xhabn,
      I_FinancialStatementItem.HierarchyNode                                                                 as id,
      I_FinancialStatementItem.ParentNode                                                                    as parent,
      I_FinancialStatementItem.ChildNode                                                                     as child,
      I_FinancialStatementItem.SiblingNode                                                                   as nextn,
      cast(I_FinancialStatementItem.FinStatementHierarchyLevelVal as abap.int4)                              as stufe,
      I_FinancialStatementItem.OffsettingItem                                                                as ergs2
}

union all select from P_FinStmtLeafItem
{
  key P_FinStmtLeafItem.HierarchyUniqueNodeID,
  key P_FinStmtLeafItem.UniqueParentID,
  key P_FinStmtLeafItem.versn,
  key P_FinStmtLeafItem.ergsl,
  key P_FinStmtLeafItem.ktopl,
  key P_FinStmtLeafItem.saknr,
  key P_FinStmtLeafItem.fkber,
      P_FinStmtLeafItem.type,
      P_FinStmtLeafItem.Description,
      P_FinStmtLeafItem.xsoll,
      P_FinStmtLeafItem.xhabn,
      P_FinStmtLeafItem.id,
      P_FinStmtLeafItem.parent,
      P_FinStmtLeafItem.child,
      P_FinStmtLeafItem.nextn,
      P_FinStmtLeafItem.stufe,
      P_FinStmtLeafItem.ergs2
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FINANCIALSTATEMENTITEM",
"P_FINSTMTLEAFITEM",
"T011"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/