P_FSTMT_HRY_NODE

@AbapCatalog.sqlViewName: 'PFSTMT_HR_NODE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType : { dataClass:      #CUSTOMIZING,
                           serviceQuality: #D,
                            sizeCategory:  #S }
@VDM.private: true
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_FSTMT_HRY_NODE 
 
  as select from        hrrp_node as node
       inner join hrrp_node as parnode
                 on node.hryid        = parnode.hryid    and
                    node.hryver       = parnode.hryver   and
                    node.parnode      = parnode.hrynode  and
                    node.hryvalto     = parnode.hryvalto and
                    parnode.nodecls   = ''               and
                    parnode.nodetype  = 'N'
     left outer to one join hrrp_node as exclnode
                 on node.hryid        = exclnode.hryid    and
                    node.hryver       = exclnode.hryver   and
                    node.parnode      = exclnode.hrynode  and
                    node.hryvalto     = exclnode.hryvalto and
                    exclnode.nodecls  = ''                and
                    ( exclnode.nodetype  = 'A' or
                      exclnode.nodetype  = 'K' or
                      exclnode.nodetype  = 'M' or
                      exclnode.nodetype  = 'B' or 
                      exclnode.nodetype  = 'J' or 
                      exclnode.nodetype  = 'V' )   
                                                          
{
  key node.hryid,
  key node.hryver,
  key node.nodecls,
  key node.hrynode as childnode,
  key node.parnode as hrynode,
  key node.hryvalto,
      node.hryvalfrom,
      case  node.parnode
        when exclnode.hrynode
        then ''
        else node.nodetype end as nodetype,
      parnode.parnode as parnode,  
      parnode.hryseqnbr,
      parnode.hrylevel  
}
   where node.nodetype = 'D'     // nodetype '' => exclude entries from left outer join

 
// union AKMBJV         

  union select from        hrrp_node as node
     inner join hrrp_node as parnode
                 on node.hryid        = parnode.hryid    and
                    node.hryver       = parnode.hryver   and
                    node.parnode      = parnode.hrynode  and
                    node.hryvalto     = parnode.hryvalto and
                    parnode.nodecls   = ''               and
                    parnode.nodetype  = 'N'
{
  key node.hryid,
  key node.hryver,
  key node.nodecls,
  key node.nodevalue as childnode,
  key parnode.hrynode as hrynode,
  key node.hryvalto,
      node.hryvalfrom,
      node.nodetype,
      parnode.parnode as parnode,
      parnode.hryseqnbr,
      parnode.hrylevel  
}
   where ( node.nodetype = 'A' or 
           node.nodetype = 'K' or 
           node.nodetype = 'M' or 
           node.nodetype = 'B' or 
           node.nodetype = 'J' or 
           node.nodetype = 'V' ) 
// union N-Entries belonging to root node ( like 00NOTASSGND )         

  union select from        hrrp_node as root
     inner join hrrp_node as node
                 on root.hryid     = node.hryid    and
                    root.hryver    = node.hryver   and
                    root.hrynode   = node.parnode  and
                    root.hryvalto  = node.hryvalto and
                    node.nodecls      = ''         and
                    node.nodetype     = 'N'
{
  key node.hryid,
  key node.hryver,
  key node.nodecls,
  key node.hrynode as childnode,
  key node.parnode as hrynode,
  key node.hryvalto,
      node.hryvalfrom,
      node.nodetype,
      '' as parnode,
      root.hryseqnbr,
      root.hrylevel  
}
   where root.nodetype = 'R' 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_NODE"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/