P_FQMFLOWACTUALCASH

@VDM.private: true
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'PFQMFLOWACTCASH'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AbapCatalog.preserveKey: true
define view P_FQMFLOWACTUALCASH
  as select from fqm_flow                      as fqm_flow 
    inner join   P_FQMFLWCATKFIGCSHPOS         as flowcat        on fqm_flow.flow_category = flowcat.FlowCategory
    inner join   P_LdngLdgrGlobCrcyTranslation as globalCurrency on fqm_flow.company_code  = globalCurrency.CompanyCode 
    inner join   t001                          as t001           on fqm_flow.company_code  = t001.bukrs
    left outer to one join   t012              as t012           on t012.bukrs             = fqm_flow.company_code
                                                                and t012.hbkid             = fqm_flow.house_bank 
                                                 
                                                
{

key fqm_flow.flow_id                   as CashFlowID,
key fqm_flow.valid_from                as ValidFrom,
    fqm_flow.valid_to                  as ValidTo,
  
    fqm_flow.company_code              as CompanyCode,
    fqm_flow.certainty_level           as CertaintyLevel, 
    @Semantics.amount.currencyCode: 'CURRENCY'
    fqm_flow.amount                    as Amount,
    @Semantics.currencyCode: true
    fqm_flow.currency                  as Currency,
    @Semantics.amount.currencyCode: 'BASECURRENCY'
    fqm_flow.base_amount               as BaseAmount,
    @Semantics.currencyCode: true
    case fqm_flow.base_currency
       when ''
         then t001.waers
       else fqm_flow.base_currency end as BaseCurrency,
    globalCurrency.GlobalCurrency,
    globalCurrency.ExchangeRateType,
    
    // accounting fields

    fqm_flow.planning_level            as PlanningLevel,
    fqm_flow.planning_group            as PlanningGroup,
    fqm_flow.fi_post_date              as PostingDate,
    fqm_flow.transaction_date          as TransactionDate,
    fqm_flow.flow_category             as FlowCategory,
    fqm_flow.flow_type                 as FlowType,
  
    case fqm_flow.fi_post_date
       when '99991230'
         then fqm_flow.transaction_date
       when '00000000' 
         then fqm_flow.transaction_date
       else fqm_flow.fi_post_date  end as CurrencyTranslationDate,
    
    // bank fields

    fqm_flow.house_bank                as HouseBank,
    fqm_flow.house_bank_account        as HouseBankAccount,
    fqm_flow.bank_account_id           as BankAccountId,
    t012.banks                         as BankCountry,
    t012.bankl                         as BankInternalID,
    // account assignment

    fqm_flow.liquidity_item            as LiquidityItem,
    fqm_flow.customer_number           as Customer,
    fqm_flow.vendor_number             as Vendor,
    fqm_flow.partner                   as Partner,
    fqm_flow.material                  as Material,
    fqm_flow.business_area             as BusinessArea,
    fqm_flow.profit_center             as ProfitCenter,
    fqm_flow.project                   as Project,
    fqm_flow.cost_center               as CostCenter,
    fqm_flow.trading_partner           as PartnerCompany,
    fqm_flow.segment                   as Segment,
    fqm_flow.assigned_company_code     as AssignedCompanyCode,
    fqm_flow.internal_reference        as DocumentReferenceID,
    fqm_flow.characteristics           as Characteristics,
    fqm_flow.assignment                as AssignmentReference,
    fqm_flow.fund                      as Fund,
    fqm_flow.grant_nbr                 as GrantID

}
where
      fqm_flow.deleted          = ''
  and fqm_flow.flg_actual       = 'X'
  and fqm_flow.certainty_level  = 'ACTUAL'     
  and fqm_flow.transaction_date < '99991231';

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_FQMFLWCATKFIGCSHPOS",
"P_LDNGLDGRGLOBCRCYTRANSLATION",
"FQM_FLOW",
"T001",
"T012"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/