P_FINS_GL_CLEAREDITEMS

@AbapCatalog.sqlViewName: 'PGLCLEAREDITEMS'
@AbapCatalog.preserveKey:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.compiler.compareFilter:true
@VDM.private: true
@VDM.viewType: #BASIC

//This view is used in the context of Reset Clearing

define view P_FINS_GL_CLEAREDITEMS
  as select from acdoca

    inner join   bkpf                                 on  bkpf.bukrs = acdoca.rbukrs
                                                      and bkpf.gjahr = acdoca.gjahr
                                                      and bkpf.belnr = acdoca.belnr

    inner join   P_FINS_REPRESENTIVE_LEDGER as ledger on  ledger.ldgrp = bkpf.ldgrp
                                                      and ledger.rldnr = acdoca.rldnr

    inner join   skb1                                 on  skb1.bukrs    = acdoca.rbukrs
                                                      and skb1.saknr    = acdoca.racct
                                                      and skb1.x_uj_clr = 'X'

{
  key acdoca.rbukrs                   as CompanyCode,
  key acdoca.gjahr                    as FiscalYear,
  key acdoca.belnr                    as AccountingDocument,
  key cast(acdoca.docln as fis_docln) as LedgerGLLineItem,
  
  
      acdoca.buzei  as AccountingDocumentItem,
      acdoca.koart  as FinancialAccountType,
      acdoca.augbl  as ClearingAccountingDocument,
      acdoca.auggj  as ClearingDocFiscalYear,
      bkpf.blart    as AccountingDocumentType,
      bkpf.bstat    as AccountingDocumentCategory,
      acdoca.zuonr  as AssignmentReference,
      bkpf.hwaer    as CompanyCodeCurrency,
      bkpf.bldat    as DocumentDate,
      acdoca.sgtxt  as DocumentItemText,
      acdoca.rebzg  as InvoiceReference,
      acdoca.rebzt  as FollowOnDocumentType,
      bkpf.budat    as PostingDate,
      ' '           as SpecialGLCode,
      ' '           as AccountingDocumentItemType, //field BUZID doesn't exist in ACDOCA

      '000'         as PaymentCardItem,
    
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      acdoca.hsl    as AmountInCompanyCodeCurrency,

      //Not needed. Never exposed to any UI

      0             as CashDiscountAmtInCoCodeCrcy,
      0             as AmountInAdditionalCurrency1, 
      0             as AmountInAdditionalCurrency2, 

      acdoca.racct  as Account
}
where
      acdoca.koart = 'S'
  and acdoca.augbl <> ''
  and bkpf.xstov   <> 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_FINS_REPRESENTIVE_LEDGER",
"ACDOCA",
"BKPF",
"SKB1"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/