P_EvtBsdRevnRecProjectIssue

@AbapCatalog.sqlViewName: 'PEBRRPROJECTRSLT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Event based rev. rec. project issue'

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED

@VDM.viewType: #CONSUMPTION
@VDM.private: true

define view P_EvtBsdRevnRecProjectIssue
  as select from           P_EvtBsdRevnRecProjectAppLog as AppLog
    inner join             I_WBSElement                 as WBSElement          on WBSElement.WBSElementObject = AppLog.WBSElementObject

    inner join             I_CompanyCode                as CompanyCode         on CompanyCode.CompanyCode = AppLog.CompanyCode

  //AppLog.AccountingPrinciple contains EvaluationArea, in future will the field Applog.AccountingPrinciple contain Ledger only

    inner join             I_EvtBasedRevnRecgnEvalArea  as EvalAreaUse         on  EvalAreaUse.CompanyCode        = AppLog.CompanyCode
                                                                               and EvalAreaUse.EvtBsdRevnEvalArea = AppLog.AccountingPrinciple

    inner join             P_Trrmonaccprin              as Trrmonaccprin       on  Trrmonaccprin.rldnr = EvalAreaUse.Ledger
                                                                               and Trrmonaccprin.bukrs = AppLog.CompanyCode
                                                                               and Trrmonaccprin.abgsl = WBSElement.ResultAnalysisInternalID


    left outer to one join I_PersonWorkAgreement_1      as PersonWorkAgreement on PersonWorkAgreement.PersonWorkAgreement = WBSElement.ResponsiblePerson

  association [0..1] to C_EvtBsdRevnRecgnProjectIssDet as _ProjectIssDetail on _ProjectIssDetail.ApplicationLog = $projection.ApplicationLog

{
  key    AppLog.ApplicationLog,
         WBSElement.WBSElement,           //prps.posid

         WBSElement.ProjectInternalID,    //prps.psphi

         WBSElement.Project,              //proj.pspid

         WBSElement.WBSElementInternalID, //prps.pspnr


         AppLog.FiscalPeriod,
         AppLog.FiscalYear,
         AppLog.ApplicationLogHandle,
         AppLog.NumberOfOpenErrorMessages,
         concat(AppLog.FiscalPeriod, concat('.', AppLog.FiscalYear) ) as ToFiscalYearPeriod,
         concat(AppLog.FiscalYear, AppLog.FiscalPeriod)               as FiscalYearPeriod,
         WBSElement.ProfitCenter,

         EvalAreaUse.Ledger                                           as Ledger,
         Trrmonaccprin.acc_principle                                  as AccountingPrinciple,

         CompanyCode.CompanyCode,
         CompanyCode.CompanyCodeName,
         CompanyCode.FiscalYearVariant,
         AppLog.Prefix,
         WBSElement.ResultAnalysisInternalID,
         AppLog.ExternalNumber,
         AppLog.WBSElementObject, //balhdr.extnumber.objnr

         
         
         //WBSElement.ResponsiblePerson,

         //PersonWorkAgreement.PersonFullName,

         
         cast(  case
                  when WBSElement.ResponsiblePerson = '00000000' or WBSElement.ResponsiblePerson is null
                     then WBSElement._EntProjectResponsiblePerson.PersonWorkAgreement
                   else
                     WBSElement.ResponsiblePerson
                 end as ps_s4_vernr preserving type )   as ResponsiblePerson,

         cast(  case
                  when WBSElement.ResponsiblePerson = '00000000' or WBSElement.ResponsiblePerson is null
                     then WBSElement._EntProjectResponsiblePerson._WorkforcePerson.PersonFullName
                   else
                     WBSElement.ResponsiblePersonName
                 end as ad_namtext preserving type )    as PersonFullName,

         _ProjectIssDetail,
         
         //for access control

         WBSElement._EntProjectResponsiblePerson,
         WBSElement._ResponsiblePerson,
         WBSElement.ResponsiblePerson as WBSResponsiblePerson
}
where
      AppLog.Prefix                   = 'PR'
  and WBSElement.WBSElementInternalID is not null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_ENTPROJECTRESPONSIBLEPERSON",
"I_EVTBASEDREVNRECGNEVALAREA",
"I_PERSONWORKAGREEMENT_1",
"I_WBSELEMENT",
"I_WORKFORCEPERSON",
"P_EVTBSDREVNRECPROJECTAPPLOG",
"P_TRRMONACCPRIN"
],
"ASSOCIATED":
[
"C_EVTBSDREVNRECGNPROJECTISSDET",
"I_ENTPROJECTRESPONSIBLEPERSON",
"I_PROJECTRESPONSIBLEPERSON"
],
"BASE":
[
"I_WBSELEMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/