P_EquipmentStatus

@AbapCatalog.sqlViewName: 'PEQUIPMENTSTATUS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE   // technically a BASIC but due to view layering a COMPOSITE)

@VDM.private: true
// provides the non-aggregated status

// to be used in aggregation views such as P_OrderStatusAggr only

define view P_EquipmentStatus
  as select from I_Equipment                as Equipment
    inner join   I_StatusObjectActiveStatus as jest on jest.StatusObject = Equipment.MaintObjectInternalID
{
  key Equipment.Equipment,
      Equipment.MaintObjectInternalID,

      case jest.StatusCode
          when 'I0099' then 'X'
          else ''
        end as EquipmentIsAvailable,
      case jest.StatusCode
        when 'I0184' then 'X'
        else ''
      end   as EquipmentIsInWarehouse,
      case jest.StatusCode
        when 'I0188' then 'X'
        else ''
      end   as EquipmentIsAtCustomer,
      case jest.StatusCode
        when 'I0186' then 'X'
        else ''
      end   as EquipmentIsAssignedToDelivery,
      case jest.StatusCode
        when 'I0076' then 'X'
        else ''
      end   as EquipmentIsMarkedForDeletion,
      case jest.StatusCode
        when 'I0100' then 'X'
        else ''
        end as EquipmentIsInstalled,
      case jest.StatusCode
        when 'I0320' then 'X'
        else ''
        end as EquipmentIsInactive,
      case jest.StatusCode
      when 'I0116' then 'X'
      else ''
      end   as EquipIsAllocToSuperiorEquip
}
where
  (
       jest.StatusCode   =    'I0099'
    or jest.StatusCode   =    'I0184'
    or jest.StatusCode   =    'I0188'
    or jest.StatusCode   =    'I0186'
    or jest.StatusCode   =    'I0076'
    or jest.StatusCode   =    'I0100'
    or jest.StatusCode   =    'I0320'
    or jest.StatusCode   =    'I0116'
  )
  and  jest.StatusObject like 'IE%';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EQUIPMENT",
"I_STATUSOBJECTACTIVESTATUS"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/