P_EquipmentSearch

//Equipment Anchor View for CDS Search Model

@AbapCatalog.sqlViewName: 'PEQUISEARCH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_LongText', '_LongTextIntNote']
@VDM.private: true
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'Equipment'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory : #L
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_EquipmentSearch
  with parameters
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_LANGUAGE
    P_Language : abap.lang,
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate : sydate
  as select from I_Equipment
  association [0..*] to I_TextObjectPlainLongText      as _LongText            on  $projection.Equipment        = _LongText.TextObjectKey
                                                                               and _LongText.TextObjectCategory = 'EQUI'
                                                                               and _LongText.TextObjectType     = 'LTXT'
  association [0..*] to I_TextObjectPlainLongText      as _LongTextIntNote     on  $projection.Equipment                = _LongTextIntNote.TextObjectKey
                                                                               and _LongTextIntNote.TextObjectCategory  = 'EQUI'
                                                                               and _LongTextIntNote.TextObjectType      = 'INTV'
  association [0..*] to I_ClfnObjectCharcValForKeyDate as _CharValueAssignment on  $projection.Equipment                = _CharValueAssignment.ClfnObjectID
                                                                               and _CharValueAssignment.ClfnObjectTable = 'EQUI'
  association [0..*] to I_ClfnObjectClassForKeyDate as _ClassAssignment        on  $projection.Equipment                = _ClassAssignment.ClfnObjectID
                                                                               and _ClassAssignment.ClfnObjectTable     = 'EQUI'
{
  key Equipment,
      EquipmentCategory,
      TechnicalObjectType,
      Plant,
      Division,
      StorageLocation,
      CreatedByUser,
      LastChangedByUser,
      CreationDate,
      LastChangeDate,
      AssetManufacturerName,
      ManufacturerPartTypeName,
      ManufacturerCountry,
      ConstructionYear,
      ConstructionMonth,
      AcquisitionDate,
      Currency,
      AcquisitionValue,
      MaintObjectInternalID,
      cast( SerialNumber as equnr) as SerialNumber,
      EquipUsagePeriodSequenceNumber,
      Material,
      Customer,
      AuthorizationGroup,
      ManufacturerSerialNumber,
      UniqueItemIdentifier,
      UniqueItemIdentifierStrucType,
      UniqueItemIdentifierRespPlant,
      AssetSynchronizationRule,
      InventoryNumber,
      GrossWeight,
      GrossWeightUnit,
      SizeOrDimensionText,
      Batch,
      OperationStartDate,
      Supplier,
      HasEquipmentData,
      MasterWarranty,
      LastChangeDateTime,
      /* Associations */
      _Batch,
      _CreatedByUser,
      _Currency,
      _CurrentTimeSegment,
      _Customer,
      _Division,
      _EquipmentCategory,
      _EquipmentText,
      _EquipmentTimeSeg,
      _GrossWeightUnit,
      _LastChangedByUser,
      _LinearAssetManagementData,
      _ManufacturerCountry,
      _MasterWarranty,
      _MasterWrntyObjectAssgmt,
      _Plant,
      _PlantMaintenancePartner,
      _SerialNumberStockSegment,
      _Status,
      _StorageLocation,
      _Supplier,
      _TechnicalObjectType,
      _LongText,
      _LongTextIntNote,
      _CharValueAssignment,
      _ClassAssignment
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EQUIPMENT"
],
"ASSOCIATED":
[
"I_BATCH",
"I_CLFNOBJECTCHARCVALFORKEYDATE",
"I_CLFNOBJECTCLASSFORKEYDATE",
"I_COUNTRY",
"I_CURRENCY",
"I_CUSTOMER",
"I_DIVISION",
"I_EQUIPMENTCATEGORY",
"I_EQUIPMENTTEXT",
"I_EQUIPMENTTIMESEG",
"I_LINEARASSETMANAGEMENTDATA",
"I_MASTERWARRANTY",
"I_MASTERWRNTYOBJECTASSGMT",
"I_PLANT",
"I_PLANTMAINTENANCEPARTNER",
"I_SERIALNUMBERSTOCKSEGMENT",
"I_STATUSOBJECTSTATUS",
"I_STORAGELOCATION",
"I_SUPPLIER",
"I_TECHNICALOBJECTTYPE",
"I_TEXTOBJECTPLAINLONGTEXT",
"I_UNITOFMEASURE",
"I_USER"
],
"BASE":
[
"I_EQUIPMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/