P_EnterpriseProjectPlnCosts

@AbapCatalog.sqlViewName: 'PENTPRJPLN'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.buffering.status: #NOT_ALLOWED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #D
@VDM.viewType: #COMPOSITE
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_EnterpriseProjectPlnCosts
  as select from I_FinancialPlanningEntryItem as _ProjCstLineItm
    inner join   P_IsLeadingLedger            as _Ledger      on _ProjCstLineItm.Ledger = _Ledger.Ledger
    inner join   I_WBSElementBasicData        as _WBS         on  _ProjCstLineItm.WBSElementInternalID = _WBS.WBSElementInternalID
                                                              and _ProjCstLineItm.ProjectInternalID    = _WBS.ProjectInternalID
    inner join   P_ProjectsWithProjCat6       as _Project     on  _ProjCstLineItm.ProjectInternalID = _Project.ProjectInternalID
                                                              and _WBS.ProjectInternalID            = _Project.ProjectInternalID
    inner join   P_PROJECTSEMTAGACC           as _SemanticTag on  _SemanticTag.ControllingArea    = _ProjCstLineItm.ControllingArea
                                                              and _SemanticTag.HierarchyNodeVal   = _ProjCstLineItm.GLAccount
                                                              and _SemanticTag.HierarchyNodeClass = _ProjCstLineItm.ChartOfAccounts


{
  key cast(cast('' as abap.char (2)) as fins_ledger_pers )                                                                as SourceLedger,
  key _Ledger.Ledger,
  key _ProjCstLineItm.CompanyCode,
  key _ProjCstLineItm.FiscalYear,
  key cast(cast('' as abap.char (10)) as farp_belnr_d )                                                                   as AccountingDocument,

  key FinancialPlanningReqTransSqnc,
  key FinancialPlanningDataPacket,
      // field ActualPlanJournalEntryItem required for representative key definition

  key cast(abs(FinancialPlanningEntryItem) as  fis_act_pln_docln )                                                        as ActualPlanJournalEntryItem,

      cast(cast('' as abap.char (6)) as fis_docln )                                                                       as LedgerGLLineItem,
      FinancialPlanningEntryItem,

      _ProjCstLineItm.ControllingArea,
      _ProjCstLineItm.GLAccount,
      _ProjCstLineItm.ChartOfAccounts,

      LedgerFiscalYear,
      cast(cast( 'P' as abap.char (1)) as fis_actual_plan_code)                                                           as ActualPlanCode,

      ////////////////////////////////////////////////////////////////////////////////////

      // G/L additional account assignments

      ////////////////////////////////////////////////////////////////////////////////////


      _ProjCstLineItm.BusinessArea,
      _ProjCstLineItm.ProfitCenter,
      _ProjCstLineItm.CostCenter,
      _Project.ProjectExternalID                                                                                          as Project,
      _ProjCstLineItm.ProjectInternalID,

      _ProjCstLineItm._WBSElementBasicData.WBSElementExternalID                                                           as WBSElement,

      _ProjCstLineItm.WBSElementInternalID,

      _ProjCstLineItm.FunctionalArea,

      _ProjCstLineItm._PartnerWBSElementBasicData.WBSElementExternalID                                                    as PartnerWBSElement,

      _ProjCstLineItm._PartnerProjectBasicData.ProjectExternalID                                                          as PartnerProject,

      PartnerProjectInternalID,
      PartnerWBSElementInternalID,

      PartnerFunctionalArea,
      PartnerCostCtrActivityType,
      OrderID,
      OrderOperation,
      /////////////////////////////////////////////////////////////////////////////////////

      // Value Fields

      /////////////////////////////////////////////////////////////////////////////////////


      @Semantics.currencyCode:true
      TransactionCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      AmountInTransactionCurrency,

      @Semantics.currencyCode:true
      CompanyCodeCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      AmountInCompanyCodeCurrency,

      @Semantics.currencyCode:true
      GlobalCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      AmountInGlobalCurrency,

      @Semantics.currencyCode:true
      ControllingObjectCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'ControllingObjectCurrency'} }
      AmountInObjectCurrency,

      /////////////////////////////////////////////////////////////////////////////////////

      // Actual value Fields

      /////////////////////////////////////////////////////////////////////////////////////


      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      cast( 0 as fis_act_wsl)                                                                                             as ActualAmountInTransactionCrcy,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      cast( 0 as fis_act_hsl)                                                                                             as ActualAmountInCompanyCodeCrcy,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      cast( 0 as fis_act_ksl)                                                                                             as ActualAmountInGlobalCurrency,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'ControllingObjectCurrency'} }
      cast(AmountInObjectCurrency as fis_act_co_osl)                                                                      as ActualAmountInObjectCurrency,

      /////////////////////////////////////////////////////////////////////////////////////

      // Plan value Fields

      /////////////////////////////////////////////////////////////////////////////////////


      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      cast(AmountInTransactionCurrency as fis_plan_wsl)                                                                   as PlanAmountInTransactionCrcy,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      cast(AmountInCompanyCodeCurrency as fis_plan_hsl)                                                                   as PlanAmountInCompanyCodeCrcy,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      cast(AmountInGlobalCurrency as fis_plan_ksl)                                                                        as PlanAmountInGlobalCurrency,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'ControllingObjectCurrency'} }
      cast(AmountInObjectCurrency as fis_plan_co_osl)                                                                     as PlndCostAmtInProjCrcy,
      /////////////////////////////////////////////////////////////////////////////

      // Mandatory fields for G/L

      ////////////////////////////////////////////////////////////////////////////


      _ProjCstLineItm.PostingDate,
      FiscalPeriod,
      FiscalYearPeriod,
      _ProjCstLineItm.FiscalYearVariant,
      FinPlngEntryItemCreatedByUser                                                                                       as AccountingDocCreatedByUser,
      cast( cast(substring( cast(FinPlngEntryItemCrtnDateTime as abap.char(30)) , 1 , 8) as abap.dats(8))  as fis_cpdat ) as CreationDate,
      ////////////////////////////////////////////////////////////////////////////

      //  .INCLUDE  ACDOC_SI_CO  Unified Journal Entry: CO fields

      ///////////////////////////////////////////////////////////////////////////


      PlanningCategory,
      cast(' ' as fins_xcommitment)                                                                                       as IsCommitment,

      _ProjCstLineItm.PartnerOrder_2                                                                                      as PartnerOrder,

      BusinessTransactionType,
      ControllingDebitCreditCode,
      CostCtrActivityType,
      'X'                                                                                                                 as IsSettled,
      _SemanticTag.SemanticTag,
      cast(_PartnerOrder.OrderCategory as fis_par_auftyp preserving type )                                                as PartnerOrderCategory,
      cast( ( case ControllingDebitCreditCode
              when 'S' then 'S'
                       else 'H'
        end )
      as fis_shkzg preserving type )                                                                                      as DebitCreditCode,
      cast('' as fins_src_awtyp)                                                                                          as SourceReferenceDocumentType,
      cast('' as fins_src_awsys)                                                                                          as SourceLogicalSystem,
      cast('' as fins_src_aworg)                                                                                          as SourceReferenceDocumentCntxt,
      cast('' as fins_src_awref)                                                                                          as SourceReferenceDocument,
      cast('000000' as fins_src_awitem)                                                                                   as SourceReferenceDocumentItem,
      cast('000000' as fins_src_awsubit)                                                                                  as SourceReferenceDocSubitem,
      _WBS.ProfitCenter                                                                                                   as WBSElementProfitCenter,
      _WBS.WBSDescription                                                                                                 as WBSDescription,
      _WBS.WBSElementObject                                                                                               as ProjectObjectNode,
      _WBS.ResponsibleCostCenter                                                                                          as ResponsibleCostCenter,
      //S/4HANA CE2202: Project Type normalization - Begin

      _WBS.ProjectType,
      //S/4HANA CE2202: Project Type normalization - End

      _Project.ProjectDescription,
      _Project.ProjectProfileCode,
      _Project.ProjectObject,
      _Project.AvailabilityControlProfile,
      _Project.AvailabilityControlIsActive,
      _Project._AvailabilityCtrlProfile.AvailyCtrlTimeRangeType,
      _Project._AvailabilityCtrlProfile.BudgetCurrencyRole,
      _Project.ProjectUUID,
      _Project.ProjectSummaryTaskUUID,
      _Project.ProcessingStatus,
      _Project.ProjectCategory,
      PlannedStartDate,
      PlannedEndDate

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_AVAILABILITYCTRLPROFILE",
"I_FINANCIALPLANNINGENTRYITEM",
"I_INTERNALORDER",
"I_PROJECTBASICDATA",
"I_WBSELEMENTBASICDATA",
"P_ISLEADINGLEDGER",
"P_PROJECTSEMTAGACC",
"P_PROJECTSWITHPROJCAT6"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/