P_EnterpriseProjectCmtmtCosts

@AbapCatalog.sqlViewName: 'PENTPRJCMTMT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.buffering.status: #NOT_ALLOWED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #D
@VDM.viewType: #COMPOSITE
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_EnterpriseProjectCmtmtCosts
  // as select from I_GLAccountLineItem   as _ProjCstLineItm

  as select from I_GLAccountLineItemRawData as _ProjCstLineItm
    inner join   I_LedgerSourceLedger       as _SourceLedger on _ProjCstLineItm.SourceLedger = _SourceLedger.SourceLedger
    inner join   I_WBSElementBasicData      as _WBS          on  _ProjCstLineItm.WBSElementInternalID = _WBS.WBSElementInternalID
                                                             and _ProjCstLineItm.ProjectInternalID    = _WBS.ProjectInternalID
    inner join   P_ProjectsWithProjCat6     as _Project      on  _ProjCstLineItm.ProjectInternalID = _Project.ProjectInternalID
                                                             and _WBS.ProjectInternalID            = _Project.ProjectInternalID
    inner join   P_PROJECTSEMTAGACC         as _SemanticTag  on  _SemanticTag.ControllingArea    = _ProjCstLineItm.ControllingArea
                                                             and _SemanticTag.HierarchyNodeVal   = _ProjCstLineItm.GLAccount
                                                             and _SemanticTag.HierarchyNodeClass = _ProjCstLineItm.ChartOfAccounts
{

  key _ProjCstLineItm.SourceLedger,
  key _SourceLedger.Ledger,
  key _ProjCstLineItm.CompanyCode,
  key FiscalYear,
  key AccountingDocument,
  key cast(cast( '00000000000000000000000' as abap.numc (23)) as fis_fp_request_tsn ) as FinancialPlanningReqTransSqnc,
  key cast(cast( '000000' as abap.numc (6)) as fis_fp_data_packet )                   as FinancialPlanningDataPacket,
      // field ActualPlanJournalEntryItem required for representative key definition

  key cast( LedgerGLLineItem as fis_act_pln_docln)                                    as ActualPlanJournalEntryItem,

      LedgerGLLineItem,
      @DefaultAggregation: #NONE
      cast(cast( 0 as abap.int4 ) as fis_fp_entry_item )                              as FinancialPlanningEntryItem,

      _ProjCstLineItm.ControllingArea,
      _ProjCstLineItm.GLAccount,
      _ProjCstLineItm.ChartOfAccounts,

      LedgerFiscalYear,
      cast(cast( 'A' as abap.char (1)) as fis_actual_plan_code)                       as ActualPlanCode,

      ////////////////////////////////////////////////////////////////////////////////////

      // G/L additional account assignments

      ////////////////////////////////////////////////////////////////////////////////////


      _ProjCstLineItm.BusinessArea,
      _ProjCstLineItm.ProfitCenter,
      _ProjCstLineItm.CostCenter,
      _Project.ProjectExternalID                                                      as Project,
      _ProjCstLineItm.ProjectInternalID,

      _ProjCstLineItm._WBSElementBasicData.WBSElementExternalID                       as WBSElement,

      _ProjCstLineItm.WBSElementInternalID,

      _ProjCstLineItm.FunctionalArea,

      _ProjCstLineItm._PartnerWBSElementBasicData.WBSElementExternalID                as PartnerWBSElement,

      _ProjCstLineItm._PartnerProjectBasicData.ProjectExternalID                      as PartnerProject,

      PartnerProjectInternalID,

      PartnerWBSElementInternalID,

      PartnerFunctionalArea,
      PartnerCostCtrActivityType,
      OrderID,
      OrderOperation,


      /////////////////////////////////////////////////////////////////////////////////////

      // Value Fields

      /////////////////////////////////////////////////////////////////////////////////////


      @Semantics.currencyCode:true
      TransactionCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      AmountInTransactionCurrency,

      @Semantics.currencyCode:true
      CompanyCodeCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      AmountInCompanyCodeCurrency,

      @Semantics.currencyCode:true
      GlobalCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      AmountInGlobalCurrency,

      @Semantics.currencyCode:true
      ControllingObjectCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'ControllingObjectCurrency'} }
      AmountInObjectCurrency,

      /////////////////////////////////////////////////////////////////////////////////////

      // Actual value Fields

      /////////////////////////////////////////////////////////////////////////////////////


      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      cast(AmountInTransactionCurrency as fis_act_wsl)                                as CmtmtCostInTransacCrcy,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      cast(AmountInCompanyCodeCurrency as fis_act_hsl)                                as CmtmtCostInCCCrcy,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      cast(AmountInGlobalCurrency as fis_act_ksl)                                     as CmtmtCostInGlobalCurrency,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'ControllingObjectCurrency'} }
      cast(AmountInObjectCurrency as fis_act_co_osl)                                  as CmtmtCostInProjCrcy,


      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      AmountInGlobalCurrency                                                          as ActlCmtmtCumltvAmtInGlobCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'ControllingObjectCurrency'} }
      AmountInObjectCurrency                                                          as AssgdValForBudgetInProjCrcy,


      PostingDate,
      FiscalPeriod,
      FiscalYearPeriod,
      _ProjCstLineItm.FiscalYearVariant,
      AccountingDocCreatedByUser,
      _ProjCstLineItm.CreationDate,
      //cast( cast( 'CMTMT' as abap.char( 5  )) as fcom_category)                       as PlanningCategory,

      cast( 'CMTMT'  as fcom_category)                                                as PlanningCategory,
      IsCommitment,
      PartnerOrder,
      BusinessTransactionType,
      ControllingDebitCreditCode,
      CostCtrActivityType,
      'X'                                                                             as IsSettled,
      _SemanticTag.SemanticTag,
      PartnerOrderCategory,
      DebitCreditCode,
      SourceReferenceDocumentType,
      SourceLogicalSystem,
      SourceReferenceDocumentCntxt,
      SourceReferenceDocument,
      SourceReferenceDocumentItem,
      SourceReferenceDocSubitem,
      cast('' as fcom_category )                                                      as PlanningCategory1,
      cast('' as fcom_category )                                                      as PlanningCategory2,
      _WBS.ProfitCenter                                                               as WBSElementProfitCenter,
      _WBS.WBSDescription                                                             as WBSDescription,
      _WBS.WBSElementObject                                                           as ProjectObjectNode,
      _WBS.ResponsibleCostCenter                                                      as ResponsibleCostCenter,
      //S/4HANA CE2202: Project Type normalization - Begin

      _WBS.ProjectType,
      //S/4HANA CE2202: Project Type normalization - End

      _Project.ProjectDescription,
      _Project.ProjectProfileCode,
      _Project.ProjectObject,
      _Project.AvailabilityControlProfile,
      _Project.AvailabilityControlIsActive,
      _Project._AvailabilityCtrlProfile.AvailyCtrlTimeRangeType,
      _Project._AvailabilityCtrlProfile.BudgetCurrencyRole,
      _Project.ProjectUUID,
      _Project.ProjectSummaryTaskUUID,
      _Project.ProcessingStatus,
      _Project.ProjectCategory,
      PlannedStartDate,
      PlannedEndDate
}

where
      _ProjCstLineItm.CompanyCode = _WBS.CompanyCode
  and IsCommitment                = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_AVAILABILITYCTRLPROFILE",
"I_GLACCOUNTLINEITEMRAWDATA",
"I_LEDGERSOURCELEDGER",
"I_PROJECTBASICDATA",
"I_WBSELEMENTBASICDATA",
"P_PROJECTSEMTAGACC",
"P_PROJECTSWITHPROJCAT6"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/