P_EntProjCostDates

@AbapCatalog.sqlViewName: 'PEPPROJCOSTDATS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.private: true
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel: {
    usageType: {
       serviceQuality:  #D,
       dataClass:       #MIXED,
       sizeCategory:    #L
   }
}
define view P_EntProjCostDates as select from P_EnterpriseProjectCosts  as CostItem
     association [1..1] to I_FiscalYearPeriodForCmpnyCode as _FiscalPeriod on  CostItem.FiscalYear   = _FiscalPeriod.FiscalYear
                                                                        and CostItem.FiscalPeriod = _FiscalPeriod.FiscalPeriod
                                                                        and CostItem.CompanyCode  = _FiscalPeriod.CompanyCode
{   
  CostItem.Project,
  CostItem.ProjectInternalID,
  case 
  when PlanningCategory = 'ACT01' then max(_FiscalPeriod._FiscalPeriodStartDate._YearMonth.LastDayOfMonthDate)  
  end as ActualEndByLtstActualCost,
  case 
  when PlanningCategory = 'PLN' then max(_FiscalPeriod._FiscalPeriodStartDate._YearMonth.LastDayOfMonthDate)  
  end as PlannedEndByLtstPlannedCost,
  case
  when PlanningCategory = 'ACT01' then min(_FiscalPeriod._FiscalPeriodStartDate._YearMonth.FirstDayOfMonthDate)  
  end as ActualStartByErlstActualCost,
  case
  when PlanningCategory = 'PLN' then min(_FiscalPeriod._FiscalPeriodStartDate._YearMonth.FirstDayOfMonthDate)  
  end as PlannedStartByErlstPlannedCost,
  case
  when PlanningCategory = 'ACT01' then min(_FiscalPeriod._FiscalPeriodStartDate._YearMonth.YearMonth)
  end as ActualCostStartYearMonth,
  case
  when PlanningCategory = 'PLN' then  min(_FiscalPeriod._FiscalPeriodStartDate._YearMonth.YearMonth)   
  end as PlannedCostStartYearMonth,
  case
  when PlanningCategory = 'ACT01' then max(_FiscalPeriod._FiscalPeriodStartDate._YearMonth.YearMonth)
  end as ActualCostEndYearMonth,
  case
  when PlanningCategory = 'PLN' then  max(_FiscalPeriod._FiscalPeriodStartDate._YearMonth.YearMonth)   
  end as PlannedCostEndYearMonth
  }
where CostItem.FiscalYearPeriod > '1900000' and (CostItem.PlanningCategory = 'PLN' or CostItem.PlanningCategory = 'ACT01' )
group by
  CostItem.Project,
  CostItem.ProjectInternalID,
  CostItem.FiscalYear,
  CostItem.PlanningCategory,
  CostItem.FiscalPeriod,
  CostItem.FiscalYearPeriod,
  _FiscalPeriod._FiscalPeriodStartDate.CalendarYear,
  _FiscalPeriod._FiscalPeriodStartDate.CalendarMonth,  
  _FiscalPeriod._FiscalPeriodStartDate.CalendarDay,
  _FiscalPeriod._FiscalPeriodStartDate._YearMonth.YearMonth,
  _FiscalPeriod._FiscalPeriodStartDate._YearMonth.LastDayOfMonthDate,
  _FiscalPeriod._FiscalPeriodStartDate._YearMonth.FirstDayOfMonthDate
  
  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CALENDARDATE",
"I_FISCALYEARPERIODFORCMPNYCODE",
"I_YEARMONTH",
"P_ENTERPRISEPROJECTCOSTS"
],
"ASSOCIATED":
[
"I_FISCALYEARPERIODFORCMPNYCODE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/