P_EngmtProjDmndByPerdKPI

@AbapCatalog.sqlViewName: 'PENGPRJDMDPRKPI'
@AbapCatalog.compiler.compareFilter: true
@VDM.private: true
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.authorizationCheck: #NOT_REQUIRED
define view P_EngmtProjDmndByPerdKPI
  as select from I_EngmntProjAssgmtToSessionUsr as A
    inner join P_EngmntProjPlanLineItemKPI as PlanData on A.EngagementProject = PlanData.EngagementProject
{
  PlanData.EngagementProject,
  PlanData.WorkPackage,
  PlanData.ResourceDemandUUID,
  PlanData.EngmtProjFinPlanVersion,
  PlanData.FiscalPeriod,
  PlanData.FiscalYear,

  
  A.EngagementProjectServiceOrg as CustomerProjectServiceOrg,
  A.IsMyProject,
  A.EngagementProjectCategory,
  A.EngagementProjectType,
  A.Customer,
  A.ProjectVisibility,
  A.EngagementProjectStage,
  A.EngagementProjectCostCenter,
  A.EngmntProjectHeaderCompanyCode,
  A.ProfitCenter,
  A.ProjectProfileCode,
  A.ControllingArea,
  A.LastChangeDateTime,
      
  sum(SupplyCostAmt)            as SupplyCostAmt,
  sum(SupplyEffortQty)          as SupplyEffortQty,
  sum(SupplyRevnAmt)            as SupplyRevnAmt,
  sum(RemainingDemandCostAmt)   as RemainingDemandCostAmt,
  sum(RemainingDemandEffortQty) as RemainingDemandEffortQty,
  sum(RemainingDemandRevnAmt)   as RemainingDemandRevnAmt,
  //  sum(DemandEffortQty)          as DemandEffortQty,

  //  sum(DemandCostAmt)            as DemandCostAmt,

  sum(PlannedExpenseCost)       as PlannedExpenseCost,
  sum(PlannedExpenseRevenue)    as PlannedExpenseRevenue
  
}
where
  IsUnitBased <> 'X'
group by
  PlanData.EngagementProject,
  PlanData.WorkPackage,
  PlanData.ResourceDemandUUID,
  PlanData.EngmtProjFinPlanVersion,
  PlanData.FiscalPeriod,
  PlanData.FiscalYear,
  A.EngagementProjectServiceOrg,
  A.IsMyProject,
  A.EngagementProjectCategory,
  A.EngagementProjectType,
  A.Customer,
  A.ProjectVisibility,
  A.EngagementProjectStage,
  A.EngagementProjectCostCenter,
  A.EngmntProjectHeaderCompanyCode,
  A.ProfitCenter,
  A.ProjectProfileCode,
  A.ControllingArea,
  A.LastChangeDateTime
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ENGMNTPROJASSGMTTOSESSIONUSR",
"P_ENGMNTPROJPLANLINEITEMKPI"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/