P_EmploymentManagerOP

@AbapCatalog.sqlViewName: 'PEMPLMANAGEROP '
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@EndUserText.label: 'Employment Manager for OnPremise'

@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

define view P_EmploymentManagerOP
  as select from    hrp1001        as Manager

    inner join      P_PDRELATION   as relat  on  relat.ObjectID              = Manager.objid
                                             and relat.ObjectType            = 'S'
                                             and relat.RelationShipDirection = 'A'
                                             and relat.ReleationShip         = '008'
                                             and relat.RelatedObjectType     = 'P'
                                             and relat.StartDate             <= $session.system_date
                                             and relat.EndDate               >= $session.system_date
    left outer join wfd_d_new_pers as switch on switch.mandt = Manager.mandt


{
  key Manager.objid         as Appointment,
  key Manager.begda         as StartDate,
      Manager.endda         as EndDate,
      Manager.sobid         as OrganizationalUnit,
      relat.RelatedObjectID as ManagerPersonWorkAgreement


}
where
       otype         =  'S'
  and  rsign         =  'A'
  and  relat         =  '012'
  and  sclas         =  'O'
  and  begda         <= $session.system_date
  and  endda         >= $session.system_date
  and(
       switch.switch is null
    or switch.switch <> 'NEW'
  )

union all select from wfd_d_keymap     as keymap
  inner join          P_PDRELATION     as relat      on  relat.ObjectID              = keymap.workforce_assgmt_id
                                                     and relat.ObjectType            = 'S'
                                                     and relat.RelationShipDirection = 'A'
                                                     and relat.ReleationShip         = '008'
                                                     and relat.RelatedObjectType     = 'P'
                                                     and relat.StartDate             <= $session.system_date
                                                     and relat.EndDate               >= $session.system_date
  inner join          wfd_d_assgmtdets as assgmtdets on keymap.workforce_assgmt_id = assgmtdets.workforce_assgmt_id
  inner join          wfd_d_new_pers   as switch     on switch.mandt = keymap.client
{
  key '00000000'                     as Appointment,
  key assgmtdets.start_date          as StartDate,
      assgmtdets.end_date            as EndDate,
      ''                             as OrganizationalUnit,
      assgmtdets.manager_work_assgmt as ManagerPersonWorkAgreement

}
where
  switch.switch = 'NEW'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_PDRELATION",
"HRP1001",
"WFD_D_ASSGMTDETS",
"WFD_D_KEYMAP",
"WFD_D_NEW_PERS"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/