P_ENTPROJECTACTCOSTS

@AbapCatalog.sqlViewName: 'PENTPROJACTCOSTS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.buffering.status: #NOT_ALLOWED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #D
@VDM.viewType: #COMPOSITE
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_ENTPROJECTACTCOSTS
  with parameters
    P_IsCommitment : fins_xcommitment
  as select from P_PROJWITHPROJCAT6         as Project
    inner join   I_GLAccountLineItemRawData as ProjCstLineItm on  ProjCstLineItm.WBSElementInternalID = Project.WBSElementInternalID
                                                              and ProjCstLineItm.ProjectInternalID    = Project.ProjectInternalID

    inner join   P_IsLeadingLedger          as Ledger         on ProjCstLineItm.SourceLedger = Ledger.SourceLedger
    inner join   P_PROJECTSEMTAGACC         as SemanticTag    on  ProjCstLineItm.ControllingArea = SemanticTag.ControllingArea
                                                              and ProjCstLineItm.GLAccount       = SemanticTag.HierarchyNodeVal
                                                              and ProjCstLineItm.ChartOfAccounts = SemanticTag.HierarchyNodeClass

  association [0..1] to I_PPM_AuthznByUsrH      as _AuthUserFin  on  _AuthUserFin.ReferencedObjectUUID = $projection.ProjectSummaryTaskUUID
                                                                 and _AuthUserFin.UserID               = $session.user
                                                                 and _AuthUserFin.Activity             = 'Financials'
  association [0..*] to I_PPM_AuthznBySubstitH  as _AuthSubstFin on  _AuthSubstFin.ReferencedObjectUUID = $projection.ProjectSummaryTaskUUID
                                                                 and _AuthSubstFin.UserID               = $session.user
                                                                 and _AuthSubstFin.Activity             = 'Financials'
  association [0..*] to I_PPM_AuthznByUserRoleH as _AuthRoleFin  on  _AuthRoleFin.ReferencedObjectUUID = $projection.ProjectSummaryTaskUUID
                                                                 and _AuthRoleFin.UserID               = $session.user
                                                                 and _AuthRoleFin.Activity             = 'Financials'
  association [0..*] to I_PPM_AuthznByUsrGrpH   as _AuthGroupFin on  _AuthGroupFin.ReferencedObjectUUID = $projection.ProjectSummaryTaskUUID
                                                                 and _AuthGroupFin.UserID               = $session.user

{
  key ProjCstLineItm._ProjectBasicData.ProjectExternalID as Project,

  key Project.ProjectInternalID,
      ProjectSummaryTaskUUID,
      ProjectUUID,
      @Semantics.currencyCode:true
      GlobalCurrency,
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'}}
      sum(ProjCstLineItm.AmountInGlobalCurrency)         as ActualAmountInGlobalCurrency,
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'}}
      cast ( 0 as fis_ksl )                              as PlanAmountInGlobalCurrency,
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'}}
      cast ( 0 as fis_ksl )                              as CmtmtCostInGlobalCurrency,
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'}}
      cast ( 0 as fis_ksl )                              as PredictedAmtInGlobalCurrency,
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'}}
      cast ( 0 as fis_ksl )                              as BaselineAmtInGlobalCrcy,
      ProjCstLineItm.IsCommitment,
      _AuthUserFin,
      _AuthSubstFin,
      _AuthRoleFin,
      _AuthGroupFin


}
where
            ProjCstLineItm.WBSElementInternalID = Project.WBSElementInternalID
  and       ProjCstLineItm.ProjectInternalID    = Project.ProjectInternalID
  and       ProjCstLineItm.CompanyCode          = Project.CompanyCode
  and       ProjCstLineItm.IsCommitment         = $parameters.P_IsCommitment
  and       not(
          (
            ControllingDebitCreditCode          = 'A'
          )
          or(
                  ControllingDebitCreditCode    = 'S'
            and(
                  BusinessTransactionType       = 'KOAO'
              or  BusinessTransactionType       = 'KOAE'
            )
            and(
                  PartnerProject                = ' '
              and PartnerOrder                  = ' '
              and PartnerSalesDocument          = ' '
              and PartnerProjectNetwork         = ' '
              and PartnerProjectNetworkActivity = ' '
              and PartnerBusinessProcess        = ' '
              and PartnerCostObject             = ' '
            )
          )
          or(
                  ControllingDebitCreditCode    = 'S'
            and(
                  BusinessTransactionType       = 'KOAO'
              or  BusinessTransactionType       = 'KOAE'
            )
            and(
                  PartnerProject                = ProjCstLineItm.Project
            )
          )
        )
group by

  ProjCstLineItm._ProjectBasicData.ProjectExternalID,

  Project.ProjectInternalID,
  ProjectSummaryTaskUUID,
  ProjectUUID,
  GlobalCurrency,
  ProjCstLineItm.IsCommitment
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_GLACCOUNTLINEITEMRAWDATA",
"I_PROJECTBASICDATA",
"P_ISLEADINGLEDGER",
"P_PROJECTSEMTAGACC",
"P_PROJWITHPROJCAT6"
],
"ASSOCIATED":
[
"I_PPM_AUTHZNBYSUBSTITH",
"I_PPM_AUTHZNBYUSERROLEH",
"I_PPM_AUTHZNBYUSRGRPH",
"I_PPM_AUTHZNBYUSRH"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/