P_EHSJobStepForIdentifyRisks

@VDM.private: true
@VDM.viewType: #CONSUMPTION
@ObjectModel.updateEnabled: false
@ObjectModel.createEnabled: false

@AccessControl.authorizationCheck: #NOT_REQUIRED

@ObjectModel.representativeKey: 'EHSJobStep'

@AbapCatalog.sqlViewName: 'PEHSJOBSTPFIDRSK'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true 

// Client handling by session 

@ClientHandling.algorithm: #SESSION_VARIABLE

// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #C,        // < 15 msec   

                         sizeCategory:  #XL,         // < 100.000.000

                         dataClass: #MASTER } 

define view P_EHSJobStepForIdentifyRisks  as
  select from I_EHSJobStepForJobAtLocation
    inner join I_EHSJobAtLocation on I_EHSJobStepForJobAtLocation.EHSJobAtLocationUUID = I_EHSJobAtLocation.EHSJobAtLocationUUID
    
 { 
  key EHSLocationUUID,
  key EHSJobUUID,
  key EHSJobStep,
  //EHSJobStepName,

  EHSJobStepForJobAtLocationUUID,
  EHSJobStepSequenceNo
} 


union
  select from I_EHSLocationRoot 
{
  // virtual record for risks not assigned to a job

  key EHSLocationUUID,
  key cast( hextobin( '00000000000000000000000000000000' ) as ehhss_job_uuid_ref preserving type ) as EHSJobUUID,
  key cast( '' as ehhss_ras_step_id ) as EHSJobStep,
  //cast( '' as ehhss_job_step_name  ) as EHSJobStepName,

  key cast( hextobin( '00000000000000000000000000000000' ) as /bobf/conf_key preserving type ) as EHSJobStepForJobAtLocationUUID,
  0 as EHSJobStepSequenceNo
}


union
  select from I_EHSJobAtLocation           
{
  // virtual record for jobs at locations for an "empty" job step; This is required for the "empty" job step in order to add new job steps to a job

  key EHSLocationUUID,
  key EHSJobUUID,
  key cast( '' as ehhss_ras_step_id ) as EHSJobStep,
  key cast( hextobin( '00000000000000000000000000000000' ) as /bobf/conf_key preserving type ) as EHSJobStepForJobAtLocationUUID,
  //cast( '' as ehhss_job_step_name  ) as EHSJobStepName,

  9999 as EHSJobStepSequenceNo
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EHSJOBATLOCATION",
"I_EHSJOBSTEPFORJOBATLOCATION",
"I_EHSLOCATIONROOT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/