P_EBWObjectPlanCosts

@AbapCatalog.sqlViewName: 'PFIEBWOBJPLNCOST'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
//@EndUserText.label: 'EBW Object Plan Cost'

@VDM.viewType: #BASIC
@VDM.private:true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
define view P_EBWObjectPlanCosts
  as select from acdocp          as _item
    inner join   I_Ledger        as _ledger  on  _ledger.Ledger          = _item.rldnr
                                             and _ledger.IsLeadingLedger = 'X'
    inner join   I_MfgOrdPlngCat as _PlngCat on _item.category = _PlngCat.PlanningCategory
{
  key rbukrs     as CompanyCode,
  key case accasty
        when 'OP' then concat( concat( 'OP', aufnr), aufps )
        else concat('OR', aufnr)
      end        as ObjectNumber,
  key aufnr      as OrderNumber,

  key racct      as GLAccount,
  key co_belkz   as ControllingDebitCreditCode,

      sum( hsl ) as hsl,
      sum( ksl ) as ksl,
      sum( osl ) as osl,
      sum( vsl ) as vsl,
      sum( bsl ) as bsl,
      sum( csl ) as csl,
      sum( dsl ) as dsl,
      sum( esl ) as esl,
      sum( fsl ) as fsl,
      sum( gsl ) as gsl
}
where
  (
       accasty                     = 'OR'
    or accasty                     = 'OP'
  )
  and  PlngCatIsForOrdReltdPlnCost = 'X'
group by
  rbukrs,
  aufnr,
  racct,
  accasty,
  aufps,
  co_belkz
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LEDGER",
"I_MFGORDPLNGCAT",
"ACDOCP"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/