P_DirectActivityAllocation

@AbapCatalog.sqlViewName: 'PDRCTACTY'
@AbapCatalog.preserveKey:true 
@AbapCatalog.compiler.compareFilter:true
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.private: true
//@EndUserText.label: 'Direct Activity Allocation Header - private view'

define view P_DirectActivityAllocation 
  as select from I_GLAccountLineItemRawData as _Header
  inner join I_AccountAssignmentType as _AAT
    on _AAT.AccountAssignmentType = _Header.AccountAssignmentType 
  
   
{
  key FiscalYear,      
      
  key ReferenceDocument,
  
  key ControllingArea,
  
  key LedgerGLLineItem,
      
      cast(_Header.CompanyCode as fis_bukrs)                            as CompanyCode, 
      cast(_Header.PartnerCompanyCode as sendercompanycode) as SenderCompanyCode,
                   
      cast(_Header.AccountingDocument as fis_belnr)                         as AccountingDocument,  
                   
      _Header._JournalEntry.AccountingDocumentHeaderText,
      
      DocumentDate,

      PostingDate,

      _Header._JournalEntry.FiscalPeriod,
      
      _Header._JournalEntry.AccountingDocumentCreationDate,
      
      cast(AccountingDocCreatedByUser as fco_cc_createdby) as AccountingDocCreatedByUser,
            
      IsReversal,
      IsReversed,      

      ReferenceDocumentType,  
      ReferenceDocumentContext,
      
      cast(_Header._JournalEntry.ExchangeRateDate as fin_currconvdat) as ExchangeRateDate,
      
      PredecessorReferenceDocument,
      ReversalReferenceDocument,
      
      @Semantics.currencyCode:true
      GlobalCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      AmountInGlobalCurrency,
        
      IsSettlement,
      IsSettled,
      
      ControllingBusTransacType,
      _Header.AccountingDocumentType,
      _ReferenceDocumentType

}

where
  ( //RKL - Leistungsverrechnung; RKLU - Umbuchung Leist.verr.

    ControllingBusTransacType = 'RKL'
    and ( BusinessTransactionCategory = 'RKL' or BusinessTransactionCategory = 'RKLU' )   
  )
  and
  ReferenceDocumentType = 'COBK'
  and
  OriginCtrlgDebitCreditCode = 'S'
  and
  _Ledger.IsLeadingLedger = 'X'
  and _Header.LogicalSystem = '' 
  and _Header._JournalEntry.SenderLogicalSystem = '' 
  and (_Header.SourceLedger = _Header._JournalEntry.LedgerGroup or _Header._JournalEntry.LedgerGroup = '' )
  

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTASSIGNMENTTYPE",
"I_GLACCOUNTLINEITEMRAWDATA",
"I_JOURNALENTRY",
"I_LEDGER"
],
"ASSOCIATED":
[
"I_REFERENCEDOCUMENTTYPE"
],
"BASE":
[
"I_GLACCOUNTLINEITEMRAWDATA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/