P_DefectAffcdObjLastEWMActnChg

@AbapCatalog.sqlViewName: 'PDEFAOEWMLSTACHG'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter:true

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
    viewType: #COMPOSITE,
    private: true
}
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M,
        serviceQuality: #A },
    representativeKey: 'DefectAffectedObject'
}
@Metadata.ignorePropagatedAnnotations: true

define view P_DefectAffcdObjLastEWMActnChg 
  as select from P_DefectAffcdObjActnParam 
     inner join I_QltyTaskFllwUpActionParam 
             on  P_DefectAffcdObjActnParam.QualityTaskInternalId = I_QltyTaskFllwUpActionParam.QualityTaskInternalId
             and I_QltyTaskFllwUpActionParam.ItemCounter = 1 // Address Single FOA Parameter


{
  key P_DefectAffcdObjActnParam.DefectInternalID,
  key P_DefectAffcdObjActnParam.DefectAffectedObject,

      max(P_DefectAffcdObjActnParam.ChangedDateTime) as LastChangedDateTime
}
  where I_QltyTaskFllwUpActionParam.QltyTaskEWMFollowUpAction is not initial 
    and (    P_DefectAffcdObjActnParam.QltyTaskFllwUpActionSts = '10'
          or P_DefectAffcdObjActnParam.QltyTaskFllwUpActionSts = '20'
               // If task has lifecycle status '20 - Completed' then FOA 'Not Successful' shall be ignored

          or ( P_DefectAffcdObjActnParam.QltyTaskFllwUpActionSts = '21'                    and
               I_QltyTaskFllwUpActionParam._QualityTask.QualityTaskLifecycleStatus <> '20'
             ) 
        )
  group by
        P_DefectAffcdObjActnParam.DefectInternalID,
        P_DefectAffcdObjActnParam.DefectAffectedObject
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_QLTYTASKFLLWUPACTIONPARAM",
"I_QUALITYTASK",
"P_DEFECTAFFCDOBJACTNPARAM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/