P_DEADSTKMVMBASE

@AbapCatalog.preserveKey: true
@AbapCatalog:
              {
                sqlViewName: 'PDEADSTKMVMBASE',
                compiler.compareFilter: true
              }
@ObjectModel:
              { 
                usageType:
                          {
                            sizeCategory: #XXL,
                            serviceQuality: #D,
                            dataClass:#TRANSACTIONAL
                          }
              }
@VDM:
      {
        viewType: #COMPOSITE,
        private: true
      }
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
define view P_DEADSTKMVMBASE 
with parameters
    P_StartDate : nsdm_reference_date,
    P_EndDate   : nsdm_reference_date
  as select from I_MaterialDocumentRecord
{
  key StockIdentifyingMaterial                          as Material,
  key Plant,
  key StockIdfgStorageLocation                          as StorageLocation,
  key StockIdentifyingBatch,
  key SpecialStockIdfgSupplier,
  key SpecialStockIdfgSalesOrder,
  key SpecialStockIdfgSalesOrderItem,
  key SpecialStockIdfgWBSElement,
  key SpecialStockIdfgCustomer,
  key SpecialStockIdfgStockOwner,
  key InventorySpecialStockType,
  key InventoryStockType,
  key MaterialBaseUnit,
  key CompanyCodeCurrency as Currency,
      sum(MatlCnsmpnQtyInMatlBaseUnit)                  as MatlCnsmpnQtyInMatlBaseUnit,
      max( case when  MatlCnsmpnQtyInMatlBaseUnit <> 0
           then PostingDate
                else cast( '00000000' as budat)
           end)                                         as CnsmpnLatestPostgDate,
      max( PostingDate )                                as MatlDocLatestPostgDate
}
where
  PostingDate >= $parameters.P_StartDate and PostingDate <= $parameters.P_EndDate
group by
  StockIdentifyingMaterial,
  Plant,
  StockIdfgStorageLocation,
  StockIdentifyingBatch,
  SpecialStockIdfgSupplier,
  SpecialStockIdfgSalesOrder,
  SpecialStockIdfgSalesOrderItem,
  SpecialStockIdfgWBSElement,
  SpecialStockIdfgCustomer,
  SpecialStockIdfgStockOwner,
  InventorySpecialStockType,
  InventoryStockType,
  MaterialBaseUnit,
  CompanyCodeCurrency

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIALDOCUMENTRECORD"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/