P_CustomerReturnItemEnhanced

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'PCRTITMENH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.private: true
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #NOT_REQUIRED

define view P_CustomerReturnItemEnhanced  
  as select from I_CustomerReturnItem              as Item
  left outer to one join P_AdvncdReturnsMgmtProcessItem   as AdvncdRetsMgmtProcessItem  on  AdvncdRetsMgmtProcessItem.RetsMgmtProcess     = Item.RetsMgmtProcess
                                                                                       and  AdvncdRetsMgmtProcessItem.RetsMgmtProcessItem = Item.CustomerReturnItem
                                                                                       and  AdvncdRetsMgmtProcessItem.ReturnsDocument     = Item.CustomerReturn
  
  left outer to one join P_AdvncdReturnsMgmtProcessStep   as AdvncdRetsMgmtProcessStep  on  AdvncdRetsMgmtProcessStep.RetsMgmtProcess          = Item.RetsMgmtProcess
                                                                                       and  AdvncdRetsMgmtProcessStep.RetsMgmtProcessItem      = Item.CustomerReturnItem
                                                                                       and  AdvncdRetsMgmtProcessStep.ReturnsDocument          = Item.CustomerReturn
                                                                                       and  AdvncdRetsMgmtProcessStep.RetsMgmtProcItmQtySplit  = '000'
                                                                                       and  AdvncdRetsMgmtProcessStep.RetsMgmtProcessStep      = '0001'
                                                                                       and  AdvncdRetsMgmtProcessStep.ReturnsDocumentType      = '00'                                                                            //  

      
//Association  

association [1..1] to I_CustomerReturnEnhanced     as _CustomerReturn            on  _CustomerReturn.CustomerReturn = $projection.CustomerReturn   
{
      @Consumption.valueHelpDefinition: [ 
        { entity: { name:    'I_CustomerReturnStdVH',
                   element: 'CustomerReturn' }
        }]      
      @ObjectModel.foreignKey.association: '_CustomerReturn'
 key  Item.CustomerReturn,
 key  Item.CustomerReturnItem,

      //Category

      Item.CustomerReturnItemCategory,

//      //Product

//      @Consumption.valueHelpDefinition: [ 

//        { entity: { name:    'I_MaterialStdVH',

//                    element: 'Material' }

//        }]

//      @API.element.releaseState: #DEPRECATED

//      @API.element.successor: 'Product'

//      Item.Material,


      @Analytics.internalName: #LOCAL
      Item.Product,
      Item.Batch,
      Item.Plant,
      Item.BillOfMaterial,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      Item.OrderQuantity,
      @Semantics.unitOfMeasure: true
      Item.OrderQuantityUnit,

      //Pricing

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Item.NetAmount,
      @Semantics.currencyCode: true
      Item.TransactionCurrency,
      
      Item.HigherLevelItem,

      //Advanced Returns Management Process 

      Item.RetsMgmtProcess,
      
      //Advanced Returns Management Process Item

      AdvncdRetsMgmtProcessItem.RetsMgmtProcessItem,
      Item.ReturnsRefundExtent,
      Item.RetsMgmtProcessingBlock,
  
      AdvncdRetsMgmtProcessItem.ReturnsRefundRjcnReason,   

      //Advanced Returns Management Process Step (Return Order)

      AdvncdRetsMgmtProcessStep.RetsMgmtProcItmQtySplit,

      AdvncdRetsMgmtProcessStep.CustRetItmFollowUpActivity,

      AdvncdRetsMgmtProcessStep.ReturnsRefundType,
      AdvncdRetsMgmtProcessStep.ReturnsRefundProcgMode,
  
      AdvncdRetsMgmtProcessStep.ReplacementMaterial,
      @Semantics.quantity.unitOfMeasure: 'ReplacementMaterialQtyUnit'
      AdvncdRetsMgmtProcessStep.ReplacementMaterialQuantity,
      //@Semantics.unitOfMeasure: true

      AdvncdRetsMgmtProcessStep.ReplacementMaterialQtyUnit,
      AdvncdRetsMgmtProcessStep.ReplacementMatlSupplyingPlant,

      //Status

      Item.ItemGeneralIncompletionStatus,
      Item.SDDocumentRejectionStatus,

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT,
                                     #TO_COMPOSITION_ROOT]
      _CustomerReturn
      
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMERRETURNITEM",
"P_ADVNCDRETURNSMGMTPROCESSITEM",
"P_ADVNCDRETURNSMGMTPROCESSSTEP"
],
"ASSOCIATED":
[
"I_CUSTOMERRETURNENHANCED"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/