P_CostCenterCommitmentUnion

@AbapCatalog.sqlViewName: 'PCSTCTRCMTMT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #COMPOSITE
@VDM.private: true
//@EndUserText.label: 'Cost Center Commitment - Private'


define view P_CostCenterCommitmentUnion 
  
  as select from P_CostCenterActualPlan as _CostCenterActualPlan 
  
{
  key FinancialPlanningReqTransSqnc,
  key FinancialPlanningDataPacket,
  key FinancialPlanningEntryItem,
  key LedgerGLLineItem,
  key SourceLedger as Ledger,
  key AccountingDocument,
  key ControllingArea,
  key CompanyCode,
  key FiscalYear,  
  key CostCenter,
  key GLAccount,
  
  FiscalYearVariant,
  FiscalPeriod,
  SourceLedger,
  Supplier,
  Material,
  CommittedQuantity,
  PlannedQuantity,
  Quantity,
  UnitOfMeasure,
  ChartOfAccounts,
  PurchasingDocument,
  PurchasingDocumentType,
  PurchasingDocumentCategory,
  PostingDate,
  
  PlanningCategory,
  
  CompanyCodeCurrency,
  GlobalCurrency,
  FunctionalCurrency,
  FreeDefinedCurrency1,
  FreeDefinedCurrency2,
  FreeDefinedCurrency3,
  FreeDefinedCurrency4,
  FreeDefinedCurrency5,
  FreeDefinedCurrency6,
  FreeDefinedCurrency7,
  FreeDefinedCurrency8,
  
  ActualAmountInFunctionalCrcy,
  CmtmtAmountInFunctionalCrcy,
  
  ActualAmountInFreeDfndCrcy1,
  ActualAmountInFreeDfndCrcy2,
  ActualAmountInFreeDfndCrcy3,
  ActualAmountInFreeDfndCrcy4,
  ActualAmountInFreeDfndCrcy5,
  ActualAmountInFreeDfndCrcy6,
  ActualAmountInFreeDfndCrcy7,
  ActualAmountInFreeDfndCrcy8,
  
  CmtmtAmountInFreeDfndCrcy1,
  CmtmtAmountInFreeDfndCrcy2,
  CmtmtAmountInFreeDfndCrcy3,
  CmtmtAmountInFreeDfndCrcy4,
  CmtmtAmountInFreeDfndCrcy5,
  CmtmtAmountInFreeDfndCrcy6,
  CmtmtAmountInFreeDfndCrcy7,
  CmtmtAmountInFreeDfndCrcy8,
  
  PlanAmountInFreeDefinedCrcy1,
  PlanAmountInFreeDefinedCrcy2,
  PlanAmountInFreeDefinedCrcy3,
  PlanAmountInFreeDefinedCrcy4,
  PlanAmountInFreeDefinedCrcy5,
  PlanAmountInFreeDefinedCrcy6,
  PlanAmountInFreeDefinedCrcy7,
  PlanAmountInFreeDefinedCrcy8,
  
  ActualAmountInCompanyCodeCrcy,
  ActualAmountInGlobalCurrency,
  CmtmtAmtInCompanyCodeCurrency,
  CmtmtAmountInGlobalCurrency,
  PlanAmountInCompanyCodeCrcy,
  PlanAmountInGlobalCurrency,
  
  CostCenterDocumentSource,
  
  //for DCL

  ValuationArea,
  ServiceDocumentType,
  Segment,
  SalesOrganization,
  ProfitCenter,
  Plant,
  OrganizationDivision,
  FinancialAccountType,
  DistributionChannel,
  BusinessArea,
  AssetClass,
  ServiceDocument,
  AccountingDocumentType,
  SalesDocument,
  OrderID,
  Customer,
  _Supplier,
  _ServiceDocument,
  _SalesDocument,
  _Order,
  _GLAccountInCompanyCode,
  _Customer,
  _AccountingDocumentType
  
}

  union all select from I_GLAccountLineItemRawData as _GLAccountLineItem

  association [0..1]    to I_PurchasingDocument    as _PurchasingDocument    on  $projection.PurchasingDocument = _PurchasingDocument.PurchasingDocument
{
  key cast('00000000000000000000000' as rspm_request_tsn)        as FinancialPlanningReqTransSqnc,
  key cast('000000' as rsdatapid)                                as FinancialPlanningDataPacket,
  key cast(0 as rsarecord)                                       as FinancialPlanningEntryItem,
  key LedgerGLLineItem,
  key cast(SourceLedger as fis_rldnr) as Ledger,
  key AccountingDocument,
  key ControllingArea,
  key CompanyCode,
  key FiscalYear,  
  key CostCenter,
  key GLAccount,
  
  FiscalYearVariant,
  FiscalPeriod,
  SourceLedger,
  Supplier,
  Product as Material,
  cast(Quantity as quan1) as CommittedQuantity,
  cast(0 as vquan1_12 ) as PlannedQuantity,
  cast(0 as quan1_12) as Quantity,
  BaseUnit as UnitOfMeasure,
  ChartOfAccounts,
  PurchasingDocument,
  _PurchasingDocument.PurchasingDocumentType,
  _PurchasingDocument.PurchasingDocumentCategory,
  PostingDate,

  cast('' as fis_category)       as PlanningCategory,

  CompanyCodeCurrency,
  GlobalCurrency,
  FunctionalCurrency,
  FreeDefinedCurrency1,
  FreeDefinedCurrency2,
  FreeDefinedCurrency3,
  FreeDefinedCurrency4,
  FreeDefinedCurrency5,
  FreeDefinedCurrency6,
  FreeDefinedCurrency7,
  FreeDefinedCurrency8,

  cast(0 as fis_vfccur12) as ActualAmountInFunctionalCrcy,
  AmountInFunctionalCurrency as CmtmtAmountInFunctionalCrcy,

  cast(0 as fis_act_osl)   as ActualAmountInFreeDfndCrcy1,
  cast(0 as fis_act_vsl)   as ActualAmountInFreeDfndCrcy2,
  cast(0 as fis_act_bsl)   as ActualAmountInFreeDfndCrcy3,
  cast(0 as fis_act_csl)   as ActualAmountInFreeDfndCrcy4,
  cast(0 as fis_act_dsl)   as ActualAmountInFreeDfndCrcy5,
  cast(0 as fis_act_esl)   as ActualAmountInFreeDfndCrcy6,
  cast(0 as fis_act_fsl)   as ActualAmountInFreeDfndCrcy7,
  cast(0 as fis_act_gsl)   as ActualAmountInFreeDfndCrcy8,

  AmountInFreeDefinedCurrency1 as CmtmtAmountInFreeDfndCrcy1,
  AmountInFreeDefinedCurrency2 as CmtmtAmountInFreeDfndCrcy2,
  AmountInFreeDefinedCurrency3 as CmtmtAmountInFreeDfndCrcy3,
  AmountInFreeDefinedCurrency4 as CmtmtAmountInFreeDfndCrcy4,
  AmountInFreeDefinedCurrency5 as CmtmtAmountInFreeDfndCrcy5,
  AmountInFreeDefinedCurrency6 as CmtmtAmountInFreeDfndCrcy6,
  AmountInFreeDefinedCurrency7 as CmtmtAmountInFreeDfndCrcy7,
  AmountInFreeDefinedCurrency8 as CmtmtAmountInFreeDfndCrcy8,

  cast(0 as fis_plan_osl) as PlanAmountInFreeDefinedCrcy1,
  cast(0 as fis_plan_vsl) as PlanAmountInFreeDefinedCrcy2,
  cast(0 as fis_plan_bsl) as PlanAmountInFreeDefinedCrcy3,
  cast(0 as fis_plan_csl) as PlanAmountInFreeDefinedCrcy4,
  cast(0 as fis_plan_dsl) as PlanAmountInFreeDefinedCrcy5,
  cast(0 as fis_plan_esl) as PlanAmountInFreeDefinedCrcy6,
  cast(0 as fis_plan_fsl) as PlanAmountInFreeDefinedCrcy7,
  cast(0 as fis_plan_gsl) as PlanAmountInFreeDefinedCrcy8,

  cast(0 as fis_hsl)                              as ActualAmountInCompanyCodeCrcy,
  cast(0 as fis_ksl)                              as ActualAmountInGlobalCurrency,
  cast(AmountInCompanyCodeCurrency as fis_hsl)    as CmtmtAmtInCompanyCodeCurrency,
  cast(AmountInGlobalCurrency as fis_ksl)         as CmtmtAmountInGlobalCurrency,
  cast(0 as fis_hsl)                              as PlanAmountInCompanyCodeCrcy,
  cast(0 as fis_ksl)                              as PlanAmountInGlobalCurrency,

  cast('CMT' as costcenterdocumentsource) as CostCenterDocumentSource,

  //for DCL

  ValuationArea,
  ServiceDocumentType,
  Segment,
  SalesOrganization,
  ProfitCenter,
  Plant,
  OrganizationDivision,
  FinancialAccountType,
  DistributionChannel,
  BusinessArea,
  AssetClass,
  ServiceDocument,
  AccountingDocumentType,
  SalesDocument,
  OrderID,
  Customer,
  _Supplier,
  _ServiceDocument,
  _SalesDocument,
  _Order,
  _GLAccountInCompanyCode,
  _Customer,
  _AccountingDocumentType

}
  where (GLAccountType = 'P' or GLAccountType = 'S')
    and (AccountAssignmentType = 'KS' or AccountAssignmentType = 'KL')
    and IsCommitment = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_GLACCOUNTLINEITEMRAWDATA",
"I_PURCHASINGDOCUMENT",
"P_COSTCENTERACTUALPLAN"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENTTYPE",
"I_CUSTOMER",
"I_GLACCOUNTINCOMPANYCODE",
"I_ORDER",
"I_SALESDOCUMENT",
"I_SRVCDOCBYDOCUMENTTYPE",
"I_SUPPLIER"
],
"BASE":
[
"P_COSTCENTERACTUALPLAN"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/