P_CollabnApplFreightRFQ1

@AbapCatalog.sqlViewName: 'PCOLLFRTRFQ1'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM:   { viewType: #CONSUMPTION,
          private: true
        }
define view P_CollabnApplFreightRFQ1

  as select from I_TenderingRequest       as TenderingRequest
    inner join   P_CollabnApplCarrierUser as CollabnApplCarrierUser on CollabnApplCarrierUser.BusinessPartnerCompany = TenderingRequest.TenderingRequestedCarrier
  association [1..1] to I_TenderingStep as _TenderingStep on $projection.TenderingStepUUID = _TenderingStep.TenderingStepUUID

{
  key cast( TenderingRequest.TenderingRequestUUID as /scmtms/vdm_frt_rfq_uuid ) as FreightRequestForQuotationUUID,
      cast( TenderingRequest.TenderingRequest as /scmtms/vdm_freight_rfq )      as FreightRequestForQuotation,
      TenderingRequest.TenderingStepUUID,
      TenderingRequest.TransportationOrderUUID,
      _TenderingStep.TenderingUUID,
      _TenderingStep._Tendering.RefTransportationOrderUUID                      as RefTransportationOrderUUID,
      _TenderingStep._Tendering.TenderingManager                                as TenderingManager,
      TenderingRequest.TenderingRequestSequenceNumber,
      TenderingRequest.TndrgReqLifeCycleStatus,
      TenderingRequest.TenderingRequestedCarrier,
      tstmp_to_dats(TenderingRequest.TenderingRequestStartDateTime,
                    abap_user_timezone($session.user,$session.client,'NULL' ),
                    $session.client,
                    'NULL' )                                                    as TenderingRequestStartDate,
      TenderingRequest.TenderingRequestStartDateTime,
      tstmp_to_dats(TenderingRequest.TenderingRequestEndDateTime,
                    abap_user_timezone($session.user,$session.client,'NULL' ) ,
                    $session.client,
                    'NULL' )                                                    as TenderingRequestEndDate,
      TenderingRequest.TenderingRequestEndDateTime,
      TenderingRequest.TenderingResponseDueDateTime,
      tstmp_to_dats(TenderingRequest.TenderingResponseDueDateTime,
                    abap_user_timezone($session.user,$session.client,'NULL' ),
                    $session.client,
                    'NULL' )                                                    as TenderingResponseDueDate,

      cast ( tstmp_current_utctimestamp() as abap.dec( 15, 0 ))                 as CurrentUTCTimestamp,
      TenderingRequest.TenderingPreferredCurrency,
      TenderingRequest.TndrgReqAbsolutePriceLimitAmt,
      TenderingRequest.TenderingVisibilitySettings,
      _TenderingStep._Tendering.TenderingLowestProposedAmount                   as TenderingLowestProposedAmount,
      _TenderingStep._Tendering.TenderingLowestProposedAmtCrcy                  as TenderingLowestProposedAmtCrcy


}
where
  (
       TenderingRequest.TndrgReqLifeCycleStatus             = '02'
    or TenderingRequest.TndrgReqLifeCycleStatus             = '03'
  )
  and(
       TenderingRequest._TenderingStep.TenderingProcessMode = 'RM'
    or TenderingRequest._TenderingStep.TenderingProcessMode = 'RA'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_TENDERING",
"I_TENDERINGREQUEST",
"I_TENDERINGSTEP",
"P_COLLABNAPPLCARRIERUSER"
],
"ASSOCIATED":
[
"I_TENDERINGSTEP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/