P_CnsldtnJrnlEntryTP

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'PJRNLENTRTP'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private:true
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
define view P_CnsldtnJrnlEntryTP
  as select from acdocu                    as a
    inner join   P_CnsldtnJrnlEntryMaxItem as _MaxItem on  _MaxItem.ConsolidationLedger         = a.rldnr
                                                       and _MaxItem.ConsolidationDimension      = a.rdimen
                                                       and _MaxItem.FiscalYear                  = a.ryear
                                                       and _MaxItem.ConsolidationDocumentNumber = a.docnr
                                                       and _MaxItem.ConsolidationPostingItem    = a.docln
{
  key    rldnr                                                                                        as ConsolidationLedger,
  key    rdimen                                                                                       as ConsolidationDimension,
  key    ryear                                                                                        as FiscalYear,
  key    docnr                                                                                        as ConsolidationDocumentNumber,
         a.rvers                                                                                      as ConsolidationVersion,
         a.poper                                                                                      as FiscalPeriod,
         a.ritclg                                                                                     as ConsolidationChartOfAccounts,
         a.plevl                                                                                      as PostingLevel,
         a.docty                                                                                      as ConsolidationDocumentType,
         a.sgtxt                                                                                      as DocumentItemText,
         cast ( case
                   when a.plevl = '20' then ''
                   when a.plevl = '30' then ''
                   when a.plevl = '' then ''
                   else a.rbunit
                end as fc_bunit )                                                                     as ConsolidationUnit,

         cast ( case
                     when a.plevl = '30' then  a.rcongr
                     else ''
                  end as fc_congr )                                                                   as ConsolidationGroup,

         cast ( case
                     when a.plevl = '20' and a.rbunit > a.rbuptr then a.rbuptr
                     when a.plevl = '20' then a.rbunit
                     else ''
                     end as fc_bunit1  )                                                              as ConsolidationUnit1,
         cast ( case
                  when a.plevl = '20' and a.rbunit > a.rbuptr then a.rbunit
                  when a.plevl = '20' then a.rbuptr
                  else ''
                  end as fc_bunit2 )                                                                  as ConsolidationUnit2,
         a.budat                                                                                      as PostingDate,
         a.cpudt                                                                                      as CreationDate,
         a.cputm                                                                                      as CreationTime,
         a.usnam                                                                                      as UserID,
         a.coicu                                                                                      as InvesteeConsolidationUnit,
         a.coiac                                                                                      as InvestmentActivityType,
         a.coinr                                                                                      as InvestmentActivity,
         a.refdocnr                                                                                   as RefConsolidationDocumentNumber,
         a.orndocnr                                                                                   as ReversedDocument,
         a.rvsdocnr                                                                                   as ReverseDocument,
         a.revyear                                                                                    as ConsolidationDocReversalYear,
         cast( case
                 when a.orndocnr <> '' then 'X'
                 else ''
                 end as fc_rvsind )                                                                   as IsReversalDocument,
         a.docnr                                                                                      as CnsldtnDocumentNumberForEdit,
         a.bunnr                                                                                      as CnsldtnGroupJrnlEntryBundle
} where plevl = '01' or plevl = '0C' or plevl = '10' or plevl = '20' or plevl = '30' 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_CNSLDTNJRNLENTRYMAXITEM",
"ACDOCU"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/