P_CndnContr_ValueHelp

@AbapCatalog.sqlViewName: 'PWCBCOCOVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #BASIC
@VDM.private: true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XL
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: [ '_ContractTypeText' ]
@Metadata.ignorePropagatedAnnotations: true
// 'Search Help for Condition Contracts'

define view P_CndnContr_ValueHelp
  as select from wcocoh

  association [0..1] to R_CndnContrType       as _ContractType        on $projection.contract_type = _ContractType.CndnContrType
  association [0..*] to R_CndnContrTypeText   as _ContractTypeText    on $projection.contract_type = _ContractTypeText.CndnContrType
  association [0..1] to P_WLF_CDS_LFA1_BG     as _Supplier            on $projection.vend_owner = _Supplier.vendor_account
  association [0..1] to P_WLF_CDS_KNA1_BG     as _Customer            on $projection.cust_owner = _Customer.customer_account
  association [0..1] to P_WLF_CDS_LFA1_BG     as _PriorSupplier       on $projection.kolif = _PriorSupplier.vendor_account
  association [0..1] to P_WLF_CDS_PERNR_BEGRU as _PersonWorkAgreement on $projection.person_owner = _PersonWorkAgreement.Pernr

{
  key num,
      contract_type,
      vend_owner,
      cust_owner,
      reference,
      assignment,
      ext_partner,
      created_by,
      created_on,
      rec_time,
      ekorg,
      ekgrp,
      vkorg,
      vtweg,
      spart,
      deact,
      date_from,
      date_to,
      ext_num,
      vkgrp,
      vkbur,
      process_category,
      cast( _ContractTypeText[1: Language = $session.system_language ].CndnContrTypeDesc as wcb_text preserving type ) as text_contrtype,
      _ContractType.CndnContrPartnerCat                                                                                as owner_type,
      _ContractType.CndnContrHasNoConditions                                                                           as no_condition,
      _Customer.customer_name                                                                                          as name1_kna1,
      _Supplier.supplier_name                                                                                          as name1_lfa1,
      category,
      kolif,
      bukrs,
      pers_kostl,
      person_owner,
      guid,
      cast( _ContractType.CndnContrSettlmtType as wb2_rebate_type preserving type )                                    as rebate_type,
      _ContractType.CndnContrEligibleCat                                                                               as eligible_type,
      _ContractType.BusVolFldCombnSet                                                                                  as busvolbase_type,
      cast( _ContractType.CnConMnlSettlmtAllwncCat as wb2_manual_settl_docs_allowed preserving type )                  as man_settl_docs,
      _Supplier.vendor_begru                                                                                           as vend_owner_begru,
      _Customer.customer_begru                                                                                         as cust_owner_begru,
      _PriorSupplier.vendor_begru                                                                                      as kolif_begru,
      _PersonWorkAgreement.pernr_begru                                                                                 as person_owner_begru

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_WLF_CDS_KNA1_BG",
"P_WLF_CDS_LFA1_BG",
"P_WLF_CDS_PERNR_BEGRU",
"R_CNDNCONTRTYPE",
"R_CNDNCONTRTYPETEXT",
"WCOCOH"
],
"ASSOCIATED":
[
"P_WLF_CDS_KNA1_BG",
"P_WLF_CDS_LFA1_BG",
"P_WLF_CDS_PERNR_BEGRU",
"R_CNDNCONTRTYPE",
"R_CNDNCONTRTYPETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/