P_CmmdtyFinTransactionHeader

@AbapCatalog: { sqlViewName:            'PCMMFTRANSHDR',
                compiler.compareFilter: true }

@AccessControl.authorizationCheck: #NOT_REQUIRED

@VDM: { viewType: #COMPOSITE,
        private: true }

@ObjectModel.usageType: { serviceQuality: #C,
                          sizeCategory:   #L,
                          dataClass:      #TRANSACTIONAL }

@ClientHandling.algorithm: #SESSION_VARIABLE

//@EndUserText.label: 'Commodity Financial Transaction Header'


define view P_CmmdtyFinTransactionHeader

  as select from vtbfha as FinTran_Header

  association [1..1] to I_FinancialTransaction      as _FinTran      on  $projection.CompanyCode          = _FinTran.CompanyCode
                                                                     and $projection.FinancialTransaction = _FinTran.FinancialTransaction
  association [1..1] to I_CompanyCode               as _CompanyCode  on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..1] to I_FinancialinstrProductType as _ProductType  on  $projection.FinancialInstrumentProductType = _ProductType.FinancialInstrumentProductType
  association [1..1] to I_BusinessPartner           as _Counterparty on  $projection.Counterparty = _Counterparty.BusinessPartner
{
  key FinTran_Header.bukrs                                                           as CompanyCode,
  key FinTran_Header.rfha                                                            as FinancialTransaction,

      cast(FinTran_Header.rfhazul as ftr_gen_fin_instr_last_act_act preserving type) as FinInstrLastActiveActivity,

      FinTran_Header.cruser                                                          as CreatedByUser,
      FinTran_Header.dcrdat                                                          as FinTransCreationDate,
      FinTran_Header.tcrtim                                                          as FinTransCreationTime,

      FinTran_Header.upuser                                                          as LastChangedByUser,
      FinTran_Header.dupdat                                                          as LastChangeDate,
      FinTran_Header.tuptim                                                          as FinInstrumentLastChangedTime,

      FinTran_Header.dblfz                                                           as TermStartDate,
      FinTran_Header.delfz                                                           as TermEndDate,

      cast(FinTran_Header.sanlf as ftr_gen_fin_instr_prod_categ preserving type)     as FinancialInstrProductCategory,
      FinTran_Header.sfgtyp                                                          as FinInstrTransactionCategory,
      FinTran_Header.sgsart                                                          as FinancialInstrumentProductType,
      FinTran_Header.sfhaart                                                         as FinancialInstrTransactionType,

      cast(FinTran_Header.kontrh   as rkontrah_new preserving type)                  as Counterparty,

      FinTran_Header.hedge_book                                                      as FinancialTransactionHedgeBook,
      FinTran_Header.rportb                                                          as FinancialTransactionPortfolio,
      FinTran_Header.hedge_class                                                     as FinTransHedgingClassification,

      /* Associations */
      _FinTran,
      _CompanyCode,
      _ProductType,
      _Counterparty
}
where
  (
       FinTran_Header.sanlf  =  '800' // Commodity Forward

    or FinTran_Header.sanlf  =  '810' // Commodity Swap

  )
  and  FinTran_Header.saktiv <> '3' // Reveresed

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"VTBFHA"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_COMPANYCODE",
"I_FINANCIALINSTRPRODUCTTYPE",
"I_FINANCIALTRANSACTION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/