P_ClfnCharcOverwrite

@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'PNGCCHR13'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_ALLOWED
@VDM.private: true
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #NONE

@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #MASTER
define view P_ClfnCharcOverwrite
  as select from I_ClfnCharcBasic as Characteristic 
  
      join I_ClfnClassCharcBasic as ClassCharc on 
        ClassCharc.OverwrittenCharcInternalID = Characteristic.CharcInternalID
        
      join I_ClfnCharcBasic as OriginalCharc on 
        OriginalCharc.CharcInternalID = ClassCharc.CharcInternalID        
{
  key Characteristic.CharcInternalID,
  key OriginalCharc.TimeIntervalNumber,
      OriginalCharc.Characteristic,
      OriginalCharc.CharcStatus,
      OriginalCharc.CharcDataType,
      OriginalCharc.CharcLength,
      OriginalCharc.CharcDecimals,
      OriginalCharc.CharcTemplate,
      OriginalCharc.ValueIsCaseSensitive,
      OriginalCharc.CharcConversionRoutine,
      OriginalCharc.CharcGroup,
      OriginalCharc.CharcValueUnit,
      OriginalCharc.Currency,      
      OriginalCharc.CharcExponentFormat,
      OriginalCharc.CharcExponentValue,
      OriginalCharc.NegativeValueIsAllowed,
      @Semantics.businessDate.from: true
      OriginalCharc.ValidityStartDate,
      @Semantics.businessDate.to: true
      OriginalCharc.ValidityEndDate,         
      OriginalCharc.ChangeNumber,
      OriginalCharc.IsDeleted,
      OriginalCharc.DocumentInfoRecordDocType,
      OriginalCharc.DocumentInfoRecordDocNumber,
      OriginalCharc.DocumentInfoRecordDocVersion,
      OriginalCharc.DocumentInfoRecordDocPart,
      OriginalCharc.CharcMaintAuthGrp,
      OriginalCharc.CharcReferenceTable,
      OriginalCharc.CharcReferenceTableField,
      OriginalCharc.CharcCheckTable,
      OriginalCharc.CharcCheckFunctionModule,
      OriginalCharc.CharcSelectedSet,
      OriginalCharc.Plant,
      OriginalCharc.CharcCatalogType,
      OriginalCharc.CreatedByUser,
      OriginalCharc.CreationDate,
      OriginalCharc.LastChangedByUser,
      OriginalCharc.LastChangeDate,
      case when Characteristic.ValueIntervalAllowedCode = '*'
        then cast ( OriginalCharc.ValueIntervalAllowedCode as valueintervalisallowed preserving type )
        else cast ( Characteristic.ValueIntervalAllowedCode as valueintervalisallowed preserving type )
      end as ValueIntervalIsAllowed, // casting: representation term needs to change from code to indicator

      case when Characteristic.AdditionalValueAllowedCode = '*'
        then cast ( OriginalCharc.AdditionalValueAllowedCode as additionalvalueisallowed preserving type )
        else cast ( Characteristic.AdditionalValueAllowedCode  as additionalvalueisallowed preserving type )
      end as AdditionalValueIsAllowed, // casting: representation term needs to change from code to indicator

      case when Characteristic.CharcReadOnlyCode = '*'
        then cast ( OriginalCharc.CharcReadOnlyCode as charcisreadonly preserving type )
        else cast ( Characteristic.CharcReadOnlyCode as charcisreadonly preserving type )
      end as CharcIsReadOnly, // casting: representation term needs to change from code to indicator

      case when Characteristic.CharcHiddenCode = '*'
        then cast ( OriginalCharc.CharcHiddenCode as charcishidden preserving type )
        else cast ( Characteristic.CharcHiddenCode as charcishidden preserving type )
      end as CharcIsHidden, // casting: representation term needs to change from code to indicator

      case when Characteristic.CharcEntryNotFormatCtrldCode = '*'
        then cast ( OriginalCharc.CharcEntryNotFormatCtrldCode as charcentryisnotformatctrld preserving type ) 
        else cast ( Characteristic.CharcEntryNotFormatCtrldCode as charcentryisnotformatctrld preserving type )
      end as CharcEntryIsNotFormatCtrld, // casting: representation term needs to change from code to indicator

      case when Characteristic.CharcTemplateDisplayedCode = '*'
        then cast ( OriginalCharc.CharcTemplateDisplayedCode as charctemplateisdisplayed preserving type )
        else cast ( Characteristic.CharcTemplateDisplayedCode as charctemplateisdisplayed preserving type )
      end as CharcTemplateIsDisplayed, // casting: representation term needs to change from code to indicator

      case when Characteristic.EntryRequiredCode = '*'
        then cast ( OriginalCharc.EntryRequiredCode as entryisrequired preserving type )
        else cast ( Characteristic.EntryRequiredCode as entryisrequired preserving type )
      end as EntryIsRequired, // casting: representation term needs to change from code to indicator

      case when Characteristic.MultipleValuesAllowedCode = '*'
        then cast ( OriginalCharc.MultipleValuesAllowedCode as multiplevaluesareallowed preserving type )
        else cast ( Characteristic.MultipleValuesAllowedCode as multiplevaluesareallowed preserving type )
      end as MultipleValuesAreAllowed, // casting: representation term needs to change from code to indicator

      OriginalCharc.CharcLastChangedDateTime
}
  where Characteristic.CharcIdentificationCode = 'KL' // only overwritten characteristics


/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CLFNCHARCBASIC",
"I_CLFNCLASSCHARCBASIC"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/