P_ClearedItem2

@AbapCatalog.sqlViewName: 'PCLRDITM2' 
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #CONSUMPTION
@VDM.private: true
@AccessControl.authorizationCheck: #NOT_ALLOWED
@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_ClearedItem2 as
//Support of Intercompany Use Case 

//Clearing Document belongs to an Intercompany transaction.

//Hence the other clearing documents belonging to the same Intercompany transaction need to be

//retrieved in order to get the cleared items which they have cleared 

  select from I_JournalEntry
  
  inner join P_ClearedItem1 as CleardItem on  I_JournalEntry.CompanyCode        = CleardItem.CompanyCode
                                          and I_JournalEntry.AccountingDocument = CleardItem.ClearingJournalEntry
                                          and I_JournalEntry.FiscalYear         = CleardItem.ClearingJournalEntryFiscalYear 
{
  key CleardItem.CompanyCode,
  key CleardItem.FiscalYear,
  key CleardItem.AccountingDocument,
  key CleardItem.AccountingDocumentItem,
  
  //The fields CompanyCode, FiscalYear, AccountingDocument and AccountingDocumentItem might not form an unique key

  //for line items which belong to an Accounting Document which has been archived and the line items still reside in 

  //the corresponding *_BCK Tables. The reason is that the value of field AccountingDocumentItem might change during 

  //the move of line items from BSEG/BSEG_ADD to the *_BCK tables.  

  //Due to that the field FinancialAccountType is part of the key.    

  key CleardItem.FinancialAccountType,
  
  CleardItem.ClearingJournalEntry,
  CleardItem.ClearingJournalEntryFiscalYear,
  CleardItem.AccountingDocumentType,
  CleardItem.AccountingDocumentCategory,
  CleardItem.AssignmentReference,
  @Semantics.currencyCode:true
  CleardItem.CompanyCodeCurrency,
  CleardItem.DocumentDate,
  CleardItem.DocumentItemText,
  CleardItem.InvoiceReference,
  CleardItem.FollowOnDocumentType,
  CleardItem.PostingDate,
  CleardItem.SpecialGLCode,
  CleardItem.Account,
  CleardItem.PaymentCardItem,
  
  @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
  cast( AmountInCompanyCodeCurrency as dmshb_farp ) as  AmountInCompanyCodeCurrency,
  
  @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
  cast( CashDiscountAmtInCoCodeCrcy as sknto_farp ) as  CashDiscountAmtInCoCodeCrcy,
      
  CleardItem.AmountInAdditionalCurrency1,
  CleardItem.AmountInAdditionalCurrency2,
  
  cast(case
    when CleardItem.AccountingDocumentItemType = 'Z' then   
      'X'
    else
      ''
  end as boole_d) as IsNetInvoiceCashDiscClearing,
  
  I_JournalEntry.IntercompanyTransaction,
  I_JournalEntry.TransactionCode
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRY",
"P_CLEAREDITEM1"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/