P_ChgRecdRefBITAfterDataMigrtn

@AbapCatalog.sqlViewName: 'PCHGRECREFBITADM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.private: true
@VDM.viewType: #COMPOSITE
define view P_ChgRecdRefBITAfterDataMigrtn
  as select from I_ChgRecdRefBOMItmBsc as reference_bit

    inner join   I_BillOfMaterialItem  as BOMItem         on  reference_bit.ChgRecRefInternalKey2 = BOMItem.BillOfMaterial
                                                          and reference_bit.ChgRecRefInternalKey3 = BOMItem.BillOfMaterialVariant
                                                          and reference_bit.ChgRecRefInternalKey4 = BOMItem.BillOfMaterialItemNumber
                                                          and BOMItem.ValidityStartDate           <= $session.system_date
                                                          and BOMItem.ValidityEndDate             >= $session.system_date

    inner join   I_MaterialBOMLink     as MaterialBOMLink on  MaterialBOMLink.BillOfMaterialCategory = 'M'
                                                          and reference_bit.ChgRecRefInternalKey1    = MaterialBOMLink.Plant
                                                          and reference_bit.ChgRecRefInternalKey2    = MaterialBOMLink.BillOfMaterial
                                                          and reference_bit.ChgRecRefInternalKey3    = MaterialBOMLink.BillOfMaterialVariant

{
  key       reference_bit.ChangeRecordReferenceUUID,
            MaterialBOMLink.Material,
            MaterialBOMLink.Plant,
            MaterialBOMLink.BillOfMaterialVariantUsage,
            MaterialBOMLink.BillOfMaterialVariant,
            BOMItem.BillOfMaterialItemUUID,
            cast( BOMItem.BillOfMaterialItemNumber as cs_sposn preserving type ) as BillOfMaterialItemNumber,
            BOMItem.BillOfMaterialComponent,
            cast( BOMItem.BillOfMaterial as cs_stlnr preserving type )           as BillOfMaterial,
            reference_bit.ChangeRecord,
            reference_bit.ChangeRecordUUID,
            reference_bit.ChangeRecordReferenceType,
            reference_bit.ChangeRecordReferenceSubtype,
            reference_bit.ChangeRecordReference,
            reference_bit.ParentChangeRecordRefUUID,
            reference_bit.IsMainReference,
            reference_bit.ChgRecRefInternalKey1,
            reference_bit.ChgRecRefInternalKey2,
            reference_bit.ChgRecRefInternalKey3,
            reference_bit.ChgRecRefInternalKey4,
            //            reference.internal_guid                             as ChgRecRefInternalGUID,

            //            reference_ext.customer_no         as ChangeRecordReferenceCustNo,

            reference_bit.CreatedByUser,
            reference_bit.CreationDateTime,
            reference_bit.LastChangedByUser,
            reference_bit.LastChangeDateTime,
            reference_bit.ChangeRecordVirtualRefInd,
            reference_bit.ChangeRecordItemRelevance,
            reference_bit.ChgRecdDataMigrationStatus,
            reference_bit.ChangeRecordItemProcgStatus,
            reference_bit.ChgRecdItmTgtSts,
            reference_bit.ChgRecdItmDSgntr,
            reference_bit.ChgRecdReasonForChange,
            reference_bit.ExpdCompltnDte,
            reference_bit.ChgRecdAuthznGrpText,
            reference_bit.ChgRecdNmbrChgSts,
            reference_bit.ChangeNumber,

            @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
            reference_bit._ChangeRecordBsc
}
where
  MaterialBOMLink.IsConfiguredMaterial = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFMATERIALITEM",
"I_CHGRECDREFBOMITMBSC",
"I_MATERIALBOMLINK"
],
"ASSOCIATED":
[
"I_CHANGERECORDBSC"
],
"BASE":
[
"I_CHGRECDREFBOMITMBSC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/