P_ChgDocItmWithDeltdUUIDField

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Change Document Item with Deleted UUID Field'
@VDM.viewType: #BASIC
@VDM.private: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MIXED
}
define view entity P_ChgDocItmWithDeltdUUIDField
  with parameters P_ChangeDocObjectClass : cdobjectcl, P_DatabaseTable : tabname, P_DatabaseTableField : fieldname
  as select from cdpos
{
  key cdpos.objectid      as ChangeDocObject,
  key cdpos.objectclas    as ChangeDocObjectClass,

  key cdpos.changenr      as ChangeDocument,
  key cdpos.tabname       as DatabaseTable,
  key cdpos.tabkey        as ChangeDocTableKey,
  key cdpos.fname         as ChangeDocDatabaseTableField,
  key cdpos.chngind       as ChangeDocItemChangeType,
  
      //cast(substring(cdpos.objectid, 1, 32) as hexadecimalcharchangedocobject preserving type) as HexadecimalCharChangeDocObject,

      case
        when cdpos.objectclas = $parameters.P_ChangeDocObjectClass
          then cast(substring(cdpos.objectid, 1, 32) as hexadecimalcharchangedocobject preserving type)
        else cast('00000000000000000000000000000000' as hexadecimalcharchangedocobject )         
      end as HexadecimalCharChangeDocObject,
      //cast(substring(cdpos.tabkey, 4, 32) as hexadecimalcharchgdoctablekey preserving type) as HexadecimalCharChgDocTableKey,      

      case
        when cdpos.objectclas = $parameters.P_ChangeDocObjectClass
          then cast(substring(cdpos.tabkey, 4, 32) as hexadecimalcharchgdoctablekey preserving type)
        else cast('00000000000000000000000000000000' as hexadecimalcharchgdoctablekey )         
      end as HexadecimalCharChgDocTableKey,      
      //cast(substring(cdpos.value_old, 1, 32) as sysuuid_c preserving type ) as DeletedForeignKeyUUID

      case
        when cdpos.objectclas = $parameters.P_ChangeDocObjectClass and cdpos.fname = $parameters.P_DatabaseTableField
          then cast(substring(cdpos.value_old, 1, 32) as sysuuid_c preserving type )
        else cast('00000000000000000000000000000000' as sysuuid_c )
      end as DeletedForeignKeyUUID
      
} where objectclas = $parameters.P_ChangeDocObjectClass
   and tabname = $parameters.P_DatabaseTable
   and cdpos.objectclas like 'ATP%'
   and fname = $parameters.P_DatabaseTableField    
   and length( tabkey ) = 35
   and fname like '%UUID'
   and chngind = 'E'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"CDPOS"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/