P_COMfgOrderTargetCube1

@AbapCatalog.sqlViewName: 'PFIMFGORDTGTCU1'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.buffering.status: #NOT_ALLOWED
@Metadata.ignorePropagatedAnnotations: true
@VDM.private:true
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
//@EndUserText.label: 'Target Costs Cube for Manufacturing Orders'

//On-the-fly target cost calculation only for manufacturing orders with order category 10/40


define view P_COMfgOrderTargetCube1
  with parameters
    P_FromFiscalYearPeriod : fis_jahrper,
    P_ToFiscalYearPeriod   : fis_jahrper,
    P_PlanningCategory     : fcom_category

  as select from P_COMFGOrderTargetCube( P_FromFiscalYearPeriod : :P_FromFiscalYearPeriod,
                                                 P_ToFiscalYearPeriod   : :P_ToFiscalYearPeriod,
                                                 P_PlanningCategory : :P_PlanningCategory )
{
  key  ControllingObject,
  key  ''    as ControllingObjectForOutput,
  key  OrderID,
  key  OrderItem,
       CompanyCode,
       Plant,
       OrderCategory,
       OrderType,
       ProducedProduct,

       sum (case
         when ControllingValueType = '05' and
              (ControllingDebitCreditCode = 'A' or ControllingDebitCreditCode = 'L')
           then AmountInGlobalCurrency
         else 0
       end ) as CreditTargetCostInGlobalCrcy,
       sum (case
         when ControllingValueType = '05' and
              (ControllingDebitCreditCode = 'H' or ControllingDebitCreditCode = 'S')
           then AmountInGlobalCurrency
         else 0
       end ) as DebitTargetCostInGlobalCrcy,


       sum (case
         when ControllingValueType = '05' and
              (ControllingDebitCreditCode = 'A' or ControllingDebitCreditCode = 'L')
           then AmountInCompanyCodeCurrency
         else 0
       end ) as CreditTargetCostInCoCodeCrcy,

       sum (case
         when ControllingValueType = '05' and
              (ControllingDebitCreditCode = 'H' or ControllingDebitCreditCode = 'S')
           then AmountInCompanyCodeCurrency
         else 0
       end ) as DebitTargetCostInCoCodeCrcy

}
group by
  ControllingObject,
  OrderID,
  OrderItem,
  CompanyCode,
  Plant,
  OrderCategory,
  OrderType,
  ProducedProduct
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_COMFGORDERTARGETCUBE"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/