P_COMFGOrderPlanCost

@AbapCatalog.sqlViewName: 'PCOMFGORDPLNCST'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.private:true 
@VDM.viewType: #COMPOSITE
define view P_COMFGOrderPlanCost 
as select from           I_FinancialPlanningEntryItem   as _PlanningEntryItem
    inner join             I_MfgOrdPlngCat                as _MfgOrdPlngCat on _MfgOrdPlngCat.PlanningCategory = _PlanningEntryItem.PlanningCategory
{
  key   Ledger,
  key   FiscalYear,
  key   FiscalPeriod,
  key   FiscalYearPeriod,
  key   ProducedProduct,
  key   GLAccount,
  key   CompanyCode,
  key   ControllingArea,
  key   WorkCenterInternalID,
  key   OrderOperation,
  key   Material,
  key   CostOriginGroup,
  key   Plant,
  key   OriginCostCenter,
  key   OriginCostCtrActivityType,
  key   PartnerCostCenter,
  key   PartnerCostCtrActivityType,
  key   _PlanningEntryItem.PlanningCategory,
  key   BusinessTransactionType,
  key   CostEstimateValidityStartDate,
  key   CostEstimateValidityEndDate,
  key   AccountAssignmentType,
  key   ControllingDebitCreditCode,
  key   PartnerAccountAssignmentType,
  key   GlobalCurrency,
  key   CompanyCodeCurrency,
  key   IsLotSizeIndependent,
  key   CostSourceUnit,
  key   SalesOrder,
  key   SalesOrderItem,      
  key   OrderID,
  key   OrderItem,
  key   cast (case AccountAssignmentType
        when 'OR' then concat(AccountAssignmentType, OrderID)
        else concat(concat(AccountAssignmentType, OrderID), OrderItem) end as j_objnr )      as   ControllingObject,
  
        FreeDefinedCurrency1,
        FreeDefinedCurrency2,
        FreeDefinedCurrency3,
        FreeDefinedCurrency4,
        FreeDefinedCurrency5,
        FreeDefinedCurrency6,
        FreeDefinedCurrency7,
        FreeDefinedCurrency8,    
        
        CostingLotSize,        
        LotSizeUnit,        

        sum(AmountInGlobalCurrency)         as AmountInGlobalCurrency,
        sum(FixedAmountInGlobalCrcy)        as FixedAmountInGlobalCurrency,
        sum(AmountInCompanyCodeCurrency)    as AmountInCompanyCodeCurrency,
        sum(case
             when AmountInGlobalCurrency <> 0
                 then cast( round(cast(division(FixedAmountInGlobalCrcy, AmountInGlobalCurrency, 6) as abap.dec(14, 6))  //fixed amount is always less than total amount here

                            * AmountInCompanyCodeCurrency, 2)
                          as abap.curr(23, 2) )
                 else 0
             end)                           as FixedAmountInCoCodeCurrency,
        sum(AmountInFreeDefinedCurrency1)   as AmountInFreeDefinedCurrency1,
        sum(AmountInFreeDefinedCurrency2)   as AmountInFreeDefinedCurrency2,
        sum(AmountInFreeDefinedCurrency3)   as AmountInFreeDefinedCurrency3,
        sum(AmountInFreeDefinedCurrency4)   as AmountInFreeDefinedCurrency4,
        sum(AmountInFreeDefinedCurrency5)   as AmountInFreeDefinedCurrency5,
        sum(AmountInFreeDefinedCurrency6)   as AmountInFreeDefinedCurrency6,
        sum(AmountInFreeDefinedCurrency7)   as AmountInFreeDefinedCurrency7,
        sum(AmountInFreeDefinedCurrency8)   as AmountInFreeDefinedCurrency8,

        //Quantity

        sum(ValuationQuantity)              as TotalQuantity


}
where
  PlngCatIsForOrdReltdPlnCost = 'X'

group by
  Ledger,
  FiscalYear,
  FiscalPeriod,
  FiscalYearPeriod,
  ProducedProduct,
  GLAccount,
  _PlanningEntryItem.CompanyCode,
  ControllingArea,
  WorkCenterInternalID,
  OrderOperation,
  Material,
  CostOriginGroup,
  Plant,
  OriginCostCenter,
  OriginCostCtrActivityType,
  PartnerCostCenter,
  PartnerCostCtrActivityType,  
  _PlanningEntryItem.PlanningCategory,
  BusinessTransactionType,
  CostEstimateValidityStartDate,
  CostEstimateValidityEndDate,
  AccountAssignmentType,
  ControllingDebitCreditCode,
  PartnerAccountAssignmentType,
  GlobalCurrency,
  CompanyCodeCurrency,
  FreeDefinedCurrency1,
  FreeDefinedCurrency2,
  FreeDefinedCurrency3,
  FreeDefinedCurrency4,
  FreeDefinedCurrency5,
  FreeDefinedCurrency6,
  FreeDefinedCurrency7,
  FreeDefinedCurrency8,
  CostingLotSize,
  LotSizeUnit,
  IsLotSizeIndependent,
  CostSourceUnit,
  SalesOrder,
  SalesOrderItem,
  OrderID,
  OrderItem
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FINANCIALPLANNINGENTRYITEM",
"I_MFGORDPLNGCAT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/