P_CN_TaxInputInvoiceItem

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog: {
    sqlViewName: 'PCNTXIIPTITM',
    compiler.compareFilter: true
}
@ObjectModel: {
    representativeKey: 'TaxInvoiceItemUUID'
}
@VDM: {
    viewType: #BASIC,
    private: true
}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #REQUIRED

define view P_CN_TaxInputInvoiceItem

  as select from txi_itm as itm
    inner join   txi_hdr as hdr on  itm.invc_uuid       = hdr.invc_uuid
                                and hdr.invc_drctn_flag = 'I' // Input Tax Invoice Only


  association [1..1] to P_CN_TaxInputInvc as _Invoice on $projection.CN_TaxInvcUUID = _Invoice.CN_TaxInvcUUID

{
  key itm.invc_item_uuid         as TaxInvoiceItemUUID,
      @ObjectModel.foreignKey.association: '_Invoice'
      hdr.invc_uuid              as CN_TaxInvcUUID,

      hdr.invc_code              as CN_TaxInvcCode,
      hdr.invc_nmbr              as CN_TaxInvcNmbr,
      itm.invc_item_nmbr         as TaxInvoiceItem,

      itm.matl_desc              as TaxInvoiceItemGoodsServiceName,
      itm.goods_nmbr             as TaxInvoiceItemGoodsNumber,
      itm.matl_spec              as TaxInvoiceItemSpecModel,
      @Semantics.unitOfMeasure
      itm.unit_of_msr            as UnitOfMeasure,
      itm.unit_of_msr_desc       as TaxInvoiceItemUnitDescription,
      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      itm.blld_qty               as TaxInvoiceItemQuantity,
      @Semantics.amount.currencyCode: '_Invoice.CN_TaxInvcCrcy'
      itm.unit_price             as TaxInvoiceItemNetUnitPrice,
      @Semantics.amount.currencyCode: '_Invoice.CN_TaxInvcCrcy'
      itm.net_amount             as TaxInvoiceItemNetAmount,
      itm.tax_rate               as TaxInvoiceItemTaxRate,
      @Semantics.amount.currencyCode: '_Invoice.CN_TaxInvcCrcy'
      itm.tax_amount             as TaxInvoiceItemTaxAmount,
      itm.toll_car_licplate      as TaxInvoiceItemTollCarLicPlate,
      itm.toll_cat_category      as TaxInvoiceItemTollCarCategory,
      itm.toll_start_datetime    as TaxInvoiceItemTollStrtDateTime,
      itm.toll_end_datetime      as TaxInvoiceItemTollEndDateTime,
      itm.mark_as_delete         as IsDeleted,

      _Invoice
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"TXI_HDR",
"TXI_ITM"
],
"ASSOCIATED":
[
"P_CN_TAXINPUTINVC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/