P_CAWorklistItemCreditDebit

@AbapCatalog.sqlViewName: 'PWLCRDTDBT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view P_CAWorklistItemCreditDebit
  as select from I_CADocumentBPItemPhysical
{
  key CADocumentNumber,
  key CABPItemNumber,
  key CARepetitionItemNumber,
  key CASubItemNumber,
      BusinessPartner,
      @Semantics.currencyCode
      TransactionCurrency,
      case when CAAmountInTransactionCurrency > 0 then cast(CAAmountInTransactionCurrency as abap.curr(23,2))
           else 0
      end as debits,
      case when CAAmountInTransactionCurrency < 0 then cast(CAAmountInTransactionCurrency as abap.curr(23,2))
           else 0
      end as credits
}
where
          CAClearingStatus             = ''
  and(
    (
          CARepetitionItemNumber       = '000'
      and CARepetitionGroup            = '000'
    )
    or    CARepetitionItemNumber != '000'
  )
  and(
          CASubstituteDocumentCategory = ''  // no substitute document

    or    CASubstituteDocumentCategory = 'P' // Promise to Pay

  ) // do not select original documents of Installment Plans and Collective Bills

union all select from I_CADocumentBPItemPhysical   as op
  inner join          I_CADocumentBPRepetitionItem as opw on  op.CADocumentNumber  = opw.CADocumentNumber
                                                          and op.CARepetitionGroup = opw.CARepetitionGroup
{
  key op.CADocumentNumber,
  key op.CABPItemNumber,
  key opw.CARepetitionItemNumber,
  key op.CASubItemNumber,
      op.BusinessPartner,
      @Semantics.currencyCode
      op.TransactionCurrency,
      case when op.CAAmountInTransactionCurrency > 0 then cast(op.CAAmountInTransactionCurrency as abap.curr(23,2))
           else 0
      end as debits,
      case when op.CAAmountInTransactionCurrency < 0 then cast(op.CAAmountInTransactionCurrency as abap.curr(23,2))
           else 0
      end as credits
}
where
      op.CAClearingStatus            = ''
  and op.CARepetitionItemNumber      = '000'
  and op.CARepetitionGroup != '000'
  and opw.CARepetitionItemIsResolved = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CADOCUMENTBPITEMPHYSICAL",
"I_CADOCUMENTBPREPETITIONITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/