P_CAClearingReasonAnalysis

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Prepare the data for clearing reason'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  usageType.serviceQuality: #D,
  usageType.sizeCategory: #XXL,
  usageType.dataClass: #TRANSACTIONAL
}
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view entity P_CAClearingReasonAnalysis
  as select from I_CADocumentBPItemLogical    as _BPItem
    join         I_CAFioApUsrClrgRsnGrpAssgmt as _ClearingReasonAssgmnt on  _BPItem.CAClearingReason                      = _ClearingReasonAssgmnt.CAClearingReason
                                                                        and _ClearingReasonAssgmnt.CAFioriApplicationUser = $session.user
{

  key        _BPItem.CADocumentNumber,
  key        _BPItem.CARepetitionItemNumber,
  key        _BPItem.CABPItemNumber,
  key        _BPItem.CASubItemNumber,
  key        _ClearingReasonAssgmnt.CAClearingReasonGroup,

             case
               when _BPItem.CADeferralDate = '00000000' then
                 _BPItem.CANetDueDate
               when _BPItem.CADeferralDate != '00000000' then
                 _BPItem.CADeferralDate
             end                                                             as CANetDueDate,

             _BPItem.CAPostingDate,
             _BPItem.CAClearingReason,
             _BPItem.CompanyCode,
             _BPItem._CompCode.CompanyCodeName,
             _BPItem.BusinessArea,
             _BPItem.Segment,
             _BPItem.BusinessPartner,
             _BPItem._BusinessPartner.BusinessPartnerFullName,
             _BPItem._BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.PostalCode,
             _BPItem.ContractAccount,
             _BPItem._CAPartner.ContractAccountName,
             _BPItem.CAContract,
             _BPItem.CASubApplication,
             _BPItem.CADocumentType,
             _BPItem.CAPaymentMethod,
             _BPItem.CAAccountDeterminationCode,
             _BPItem.Division,
             _BPItem.CAMainTransaction,
             _BPItem.CASubTransaction,
             _BPItem.CAStatisticalItemCode,
             _BPItem.CAApplicationArea,
             _BPItem.CAValueDateForClearing,
             _BPItem.CAPostingDateOfClearingDoc,
             _BPItem.CAClearingStatus,
             _BPItem.Country,

             @Semantics.amount.currencyCode: 'TransactionCurrency'
             cast (_BPItem.CAAmountInTransactionCurrency as abap.curr(23,2)) as CAAmountInTransactionCurrency,

             _BPItem.TransactionCurrency,

             // extra fields for authority checks

             _BPItem._CAPartner.CAAuthorizationGroup,
             _BPItem._ProviderContract.CAAuthorizationGroup                  as CAProviderContractAuthznGroup

}
where
  _BPItem.CAAmountInTransactionCurrency > 0


union all select from I_CADocumentBPItemLogical as _BPItem
{
  key        _BPItem.CADocumentNumber,
  key        _BPItem.CARepetitionItemNumber,
  key        _BPItem.CABPItemNumber,
  key        _BPItem.CASubItemNumber,
  key        cast('OPEN' as augrg_kk)                                        as CAClearingReasonGroup,

             case
               when _BPItem.CADeferralDate = '00000000' then
                 _BPItem.CANetDueDate
               when _BPItem.CADeferralDate != '00000000' then
                 _BPItem.CADeferralDate
             end                                                             as CANetDueDate,

             _BPItem.CAPostingDate,
             _BPItem.CAClearingReason,
             _BPItem.CompanyCode,
             _BPItem._CompCode.CompanyCodeName,
             _BPItem.BusinessArea,
             _BPItem.Segment,
             _BPItem.BusinessPartner,
             _BPItem._BusinessPartner.BusinessPartnerFullName,
             _BPItem._BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.PostalCode,
             _BPItem.ContractAccount,
             _BPItem._CAPartner.ContractAccountName,
             _BPItem.CAContract,
             _BPItem.CASubApplication,
             _BPItem.CADocumentType,
             _BPItem.CAPaymentMethod,
             _BPItem.CAAccountDeterminationCode,
             _BPItem.Division,
             _BPItem.CAMainTransaction,
             _BPItem.CASubTransaction,
             _BPItem.CAStatisticalItemCode,
             _BPItem.CAApplicationArea,
             _BPItem.CAValueDateForClearing,
             _BPItem.CAPostingDateOfClearingDoc,
             _BPItem.CAClearingStatus,
             _BPItem.Country,

             cast (_BPItem.CAAmountInTransactionCurrency as abap.curr(23,2)) as CAAmountInTransactionCurrency,

             _BPItem.TransactionCurrency,


             // extra fields for authority checks

             _BPItem._CAPartner.CAAuthorizationGroup,
             _BPItem._ProviderContract.CAAuthorizationGroup                  as CAProviderContractAuthznGroup
}
where
      CAClearingReason                      is initial
  and _BPItem.CAAmountInTransactionCurrency > 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS_2",
"I_BPCURRENTDEFAULTADDRESS",
"I_BUSINESSPARTNER",
"I_CADOCUMENTBPITEMLOGICAL",
"I_CAFIOAPUSRCLRGRSNGRPASSGMT",
"I_CAPROVIDERCONTRACTHEADER",
"I_COMPANYCODE",
"I_CONTRACTACCOUNTPARTNER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/